<%
'=================================================
'动网Dv7.0Jmail发送邮件说明：
'   Edit By YangZheng
'=================================================
Dim SendMail

Sub Jmail(email,topic,mailbody)
	on error resume next
	dim JMail
	Set JMail=Server.CreateObject("JMail.Message")
	'JMail.silent=true
	JMail.Logging=True
	JMail.Charset="gb2312"
	JMail.MailServerUserName = Dvbbs.Forum_info(12) '您的邮件服务器登录名
	JMail.MailServerPassword = Dvbbs.Forum_info(13) '登录密码
	JMail.ContentType = "text/html"
	JMail.Priority = 1
	JMail.From=Dvbbs.Forum_info(5)
	JMail.FromName = Dvbbs.Forum_info(0)
	JMail.AddRecipient email
	JMail.Subject=topic
	JMail.Body=mailbody
	JMail.Send (Dvbbs.Forum_info(4))
	Set JMail=nothing
	SendMail="OK"
	If err then SendMail="False"
end sub
	
sub Cdonts(email,topic,mailbody)
	on error resume next
	dim  objCDOMail
	Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
	objCDOMail.From =Dvbbs.Forum_info(5)
	objCDOMail.To =email
	objCDOMail.Subject =topic
	objCDOMail.BodyFormat = 0 
	objCDOMail.MailFormat = 0 
	objCDOMail.Body =mailbody
	objCDOMail.Send
	Set objCDOMail = Nothing
	SendMail="OK"
	If err then SendMail="False"
end sub

sub aspemail(email,topic,mailbody)
	on error resume next
	dim Mailer
	Set Mailer=Server.CreateObject("Persits.MailSender") 
	Mailer.Charset = "gb2312"
	Mailer.IsHTML = True
	Mailer.username = Dvbbs.Forum_info(12)	'服务器上有效的用户名
	Mailer.password = Dvbbs.Forum_info(13)	'服务器上有效的密码
	Mailer.Priority = 1
	Mailer.Host = Dvbbs.Forum_info(4)
	Mailer.Port = 25 ' 该项可选.端口25是默认值
	Mailer.From = Dvbbs.Forum_info(5)
	Mailer.FromName = Dvbbs.Forum_info(0) ' 该项可选
	Mailer.AddAddress email,email
	Mailer.Subject = topic
	Mailer.Body = mailbody
	Mailer.Send
	SendMail="OK"
	If err then SendMail="False"
end sub
%>