<!-- #include file=../inc/BBSsetup.asp -->
<!-- #include file=../inc/Board_Popfun.asp -->
<!-- #include file=../inc/Limit_Fun.asp -->
<!-- #include file=inc/Board2_fun.asp -->
<%
DEF_PubMessageEnable = 1
DEF_BBS_HomeUrl = "../"

Function DisplayBoardMastList(MasterList,Num)

	If MasterList = "" Then
		Response.Write "无"
		Exit function
	ElseIf MasterList = "?LeadBBS?" Then
		Response.Write "全体版主"
		Exit function		
	End If
	Dim temp,n,I
	Temp = split(MasterList,",")
	I = Ubound(temp,1)
	For N = 0 to I
		If N >= Num Then
			'Response.Write "..."
			Exit For
		End If
		Response.Write " <a href=" & DEF_BBS_HomeUrl & "user/LookUserInfo.asp?name=" & urlencode(temp(N)) & ">" & htmlencode(temp(n)) & "</a>"
	Next

	If N >= Num and N <= I Then
		Response.Write "<span style=""cursor:hand"" title=""更多版主: " & temp(N)
		N = N + 1
		For N = N to I
			Response.Write " " & temp(N)
		Next
		Response.Write """>...</span>"
	End If

End Function

Function LoginAccuessFul

	GBL_CHK_TempStr = ""
	If GBL_board_ID = 0 Then
		Response.Write "<table width=" & DEF_BBS_ScreenWidth & " class=TBBG9 align=center><tr height=20><td>&nbsp;社区不存在此版面，请重新选择或需要添加新社区。</td></tr></table>" & VbCrLf
		Exit Function
	End If
	If GBL_CHK_TempStr<>"" then
		Response.Write GBL_CHK_TempStr
	Else
		DisplayAnnouncesSplitPages
	End If

End Function

Sub Main

	GBL_CHK_PWdFlag = 0
	GBL_CHK_GuestFlag = 0
	initDatabase
	CheckisBoardMaster
	GBL_CHK_TempStr = ""
	BBS_SiteHead DEF_SiteNameString & " " & DEF_BBS_Name,GBL_board_ID,""
	CheckAccessLimit

	If DEF_EnableTreeView = 0 Then GBL_CHK_TempStr = "社区已经设置成禁止树形查看．"
	If GBL_CHK_TempStr = "" Then
		UpdateOnlineUserAtInfo GBL_board_ID,GBL_Board_BoardName
	%>
	<table width=<%=DEF_BBS_ScreenWidth%> border=0 cellspacing=1 cellpadding=0 align="center" bgcolor=<%=DEF_BBS_DarkColor%> class=<%If GBL_TableHeadString = "" Then
		Response.Write "TBone"
	Else
		Response.Write "TBthree"
	End If%>><tr><td>
	<table width="100%" border="0" cellspacing="0" cellpadding="0" align="center">
	<tr bgcolor=<%=DEF_BBS_Color%> class=TBthree><td colspan=2><img src=<%=DEF_BBS_HomeUrl%>images/null.gif width=2 height=2></td></tr>
	<tr bgcolor=<%=DEF_BBS_Color%> class=TBthree>
		<td height=20><%If GBL_TableHeadString = "" Then%>&nbsp;<%End If%><a href=../Announce/Announce2.asp?BoardID=<%=GBL_board_ID%>><img src=../images/<%=GBL_DefineImage%>newanc.gif width=60 height=17 border=0 align=absmiddle alt=新帖></a>
			<a href=../Announce/Announce2.asp?BoardID=<%=GBL_board_ID%>&VoteFlag=yes><img src=../images/<%=GBL_DefineImage%>newpoll.gif width=60 height=17 border=0 align=absmiddle alt=新投票></a>
			<font color=444444>讨论区</font> <a href=../Board/EBoard.asp?BoardID=<%=GBL_board_ID%>>精华区</a>
			<a href=Board.asp?BoardID=<%=GBL_board_ID%>>主题版面</a>
		</td>
		<td align=right>
			&nbsp;版主：<%DisplayBoardMastList GBL_Board_MasterList,5 %>&nbsp;
		</td>
	</tr>
	</table>
	</td></tr></table>
	<img src=../images/blank.gif width=2 height=2><br>
	<%LoginAccuessFul
	Else
		%>
	<br>
	<table width="<%=DEF_BBS_ScreenWidth%>" border="0" cellspacing="0" cellpadding="0" align="center">
	<tr>
		<td>
			<font color=ff0000 class=RedFont><b><%=GBL_CHK_TempStr%></b></font>[<a href=../User/help/help.asp#lmt>说明</a>]</td>
	</tr>
	</table>
	<%
	End If
	closeDataBase
	If GBL_CHK_TempStr <> "" Then
		Response.Write "<hr size=1 align=center width=" & DEF_BBS_ScreenWidth & " class=TBtwofont>"
		If GBL_ShowBottomSure = 0 Then GBL_SiteBottomString = ""
	End If
	SiteBottom
	If GBL_SiteBottomString <> "" Then Response.Write GBL_SiteBottomString

End Sub

Main
%>