<!--#include file="NS_Public.asp" -->
<!--#include file="MS_Public.asp" -->
<!--#include file="DS_Public.asp" -->
<!--#include file="ME_Public.asp" -->
<!--#include file="MF_Public.asp" -->
<!--#include file="SD_Public.asp" -->
<!--#include file="HS_Public.asp" -->
<!--#include file="AP_Public.asp" -->
<!--#include file="Other_Public.asp" -->
<%

Function Replace_All_Flag(f_File_Cont,f_NewsID,sysFlag,PageType)
	Dim f_REG_EX,f_REG_MATCH,f_REG_MATCHS,f_REG_PLACE_OBJ,f_TEST_LABLE_CONT_MATCHS,f_TEST_LABLE_CONT_MATCH,f_MORE_PAGES_DICT_OBJ
	Dim f_REG_Head_Str,f_REG_Tailor_Str,f_Match_Str,f_Lable_Cont,f_RERESH_OBJ,f_Sys_ID,f_Lable_Para_Value,f_Raw_Data
	Dim f_LABLE_DICT_OBJ,f_Lable,f_DICT_ITEMS_OBJ,f_DICT_KEYS_OBJ,f_i,f_j,f_ARRAY_OBJ,f_More_Pages_Flag_TF,f_NEWS_CONT_REPLACE_FLAG_OBJ
	Dim f_DICT_MATCHS,f_Replace_Flag_TF,f_NEWS_CONT_REG_OBJ,f_NEWS_CONT_MATCHS,f_Lable_News_Cont,f_Lable_One_Page_News_Cont,Str_MFFlag,Str_SysType
	f_More_Pages_Flag_TF = False
	If Request.Cookies("FoosunSUBCookie") = "" Then SubSys_Cookies
	If Request.Cookies("FoosunMFCookies") = "" Then MFConfig_Cookies
	If Request.Cookies("FoosunNSCookies") = "" Then NSConfig_Cookies
	If Request.Cookies("FoosunDSCookies") = "" And Request.Cookies("FoosunSUBCookie")("FoosunSUBDS") = 1 Then DSConfig_Cookies
	If Request.Cookies("FoosunMSCookies") = "" And Request.Cookies("FoosunSUBCookie")("FoosunSUBMS") = 1 Then MSConfig_Cookies
	f_REG_Head_Str = "{FS400_"
	f_REG_Tailor_Str = "}"
	Set f_MORE_PAGES_DICT_OBJ = Server.CreateObject(G_FS_DICT)
	Set f_LABLE_DICT_OBJ = Server.CreateObject(G_FS_DICT)
	Set f_REG_EX = New RegExp
	f_REG_EX.Pattern = f_REG_Head_Str & ".*?" & f_REG_Tailor_Str
	f_REG_EX.IgnoreCase = True
	f_REG_EX.Global = True
	Set f_REG_MATCHS = f_REG_EX.Execute(f_File_Cont)
	f_Raw_Data = f_File_Cont
	For Each f_REG_MATCH in f_REG_MATCHS
		f_Match_Str = f_REG_MATCH.Value
		f_Lable = f_Match_Str
		f_Match_Str = Replace(f_Match_Str,Chr(13) & Chr(10),"")
		Set f_REG_PLACE_OBJ = New RegExp
		f_REG_PLACE_OBJ.IgnoreCase = True
		f_REG_PLACE_OBJ.Global = True
		f_Match_Str=Get_Label_Content(f_Match_Str)
		f_REG_PLACE_OBJ.Pattern = "{FS:.*}"
		Set f_TEST_LABLE_CONT_MATCHS = f_REG_PLACE_OBJ.Execute(f_Match_Str)
		if (f_TEST_LABLE_CONT_MATCHS.Count>0) then
			for Each f_TEST_LABLE_CONT_MATCH in f_TEST_LABLE_CONT_MATCHS
				f_Lable_Para_Value = f_TEST_LABLE_CONT_MATCH.Value
				f_Sys_ID = Mid(f_Lable_Para_Value,5,2)
				f_Lable_Para_Value = Mid(f_Lable_Para_Value,8,Len(f_Lable_Para_Value) - 8)
				Str_MFFlag=False
				if Request.Cookies("FoosunSUBCookie")("FoosunSUB" & f_Sys_ID) = 1 then
					Select Case f_Sys_ID
						Case "NS"
							Set f_RERESH_OBJ = New cls_NS
						Case "MS"
							Set f_RERESH_OBJ = New cls_MS
						Case "DS"
							Set f_RERESH_OBJ = New cls_DS
						Case "ME"
							Set f_RERESH_OBJ = New cls_ME
						Case "MF"
							Set f_RERESH_OBJ = New cls_MF
							Str_MFFlag=True
						Case "SD"
							Set f_RERESH_OBJ = New cls_SD
						Case "HS"
							Set f_RERESH_OBJ = New cls_HS
						Case "AP"
							Set f_RERESH_OBJ = New cls_AP
						Case Else
							Set f_RERESH_OBJ = New cls_Other
					End Select
					If Str_MFFlag Then
						Str_SysType=sysFlag
						If PageType<>"" Then
							Str_SysType=Str_SysType&"_"&PageType
						End If 
						f_Lable_Cont = f_RERESH_OBJ.get_LableChar(f_Lable_Para_Value,f_NewsID,Str_SysType)
					Else
						f_Lable_Cont = f_RERESH_OBJ.get_LableChar(f_Lable_Para_Value,f_NewsID)
					End If
					f_Match_Str = Replace(f_Match_Str,f_TEST_LABLE_CONT_MATCH.Value,"{|}"&f_Lable_Cont&"{|}")
				End If
				Set f_RERESH_OBJ = Nothing
			Next
		End If
		If Not f_LABLE_DICT_OBJ.Exists(f_Lable) Then
			f_LABLE_DICT_OBJ.Add f_Lable,f_Match_Str
		End If
		Set f_REG_PLACE_OBJ = Nothing
	Next
	f_MORE_PAGES_DICT_OBJ.Add "-3",""
	f_DICT_ITEMS_OBJ = f_LABLE_DICT_OBJ.Items
	f_DICT_KEYS_OBJ = f_LABLE_DICT_OBJ.Keys
	Dim Str_Other,PageNum_Flag
	For f_i = 0 To f_LABLE_DICT_OBJ.Count - 1
		if Not f_More_Pages_Flag_TF then
			f_Replace_Flag_TF = False
			Set f_REG_PLACE_OBJ = New RegExp
			f_REG_PLACE_OBJ.Pattern = "{foosun_page_news}.*?{/foosun_page_news}"
			f_REG_PLACE_OBJ.IgnoreCase = True
			f_REG_PLACE_OBJ.Global = True

			Set f_DICT_MATCHS = f_REG_PLACE_OBJ.Execute(f_DICT_ITEMS_OBJ(f_i))

			if (f_DICT_MATCHS.Count>=1) And (f_More_Pages_Flag_TF=False) Then
				f_More_Pages_Flag_TF = True
				Str_Other=Split(f_DICT_ITEMS_OBJ(f_i),"{|}")
				f_ARRAY_OBJ = Split(Str_Other(1),f_DICT_MATCHS(0).Value)
				f_MORE_PAGES_DICT_OBJ.Add "-2",f_DICT_KEYS_OBJ(f_i)
				f_MORE_PAGES_DICT_OBJ.Add "-1",f_DICT_MATCHS(0).Value
				PageNum_Flag=False
				for f_j = LBound(f_ARRAY_OBJ) To UBound(f_ARRAY_OBJ)
					If Len(f_ARRAY_OBJ(f_j)) > 1 then
						If Not f_MORE_PAGES_DICT_OBJ.Exists(f_j) Then
							f_MORE_PAGES_DICT_OBJ.Add f_j,f_ARRAY_OBJ(f_j)
							PageNum_Flag=True
						End If 
					end if
				Next
				If PageNum_Flag Then
					f_Raw_Data = Replace(f_Raw_Data,f_DICT_KEYS_OBJ(f_i),Str_Other(0)&f_DICT_KEYS_OBJ(f_i)&Str_Other(2))
				End If 
				Set Str_Other=Nothing 
				f_Replace_Flag_TF = True
			Else
				f_DICT_ITEMS_OBJ(f_i)=Replace(f_DICT_ITEMS_OBJ(f_i),"{|}","")
			End If
			f_REG_PLACE_OBJ.Pattern = "\[fs\:page\]"
			Set f_DICT_MATCHS = f_REG_PLACE_OBJ.Execute(f_DICT_ITEMS_OBJ(f_i))
			Set f_NEWS_CONT_REG_OBJ = New RegExp
			f_NEWS_CONT_REG_OBJ.IgnoreCase = True
			f_NEWS_CONT_REG_OBJ.Global = True
			f_NEWS_CONT_REG_OBJ.Pattern = "\[FS\:CONTENT_START\][^\0]*\[FS\:CONTENT_END\]"
			Set f_NEWS_CONT_MATCHS = f_NEWS_CONT_REG_OBJ.Execute(f_DICT_ITEMS_OBJ(f_i))
			if (f_DICT_MATCHS.Count>=1) And (f_More_Pages_Flag_TF=False) And (f_NEWS_CONT_MATCHS.Count=1) then
				f_More_Pages_Flag_TF = True
				f_MORE_PAGES_DICT_OBJ.Add "-2",f_DICT_KEYS_OBJ(f_i)
				f_MORE_PAGES_DICT_OBJ.Add "-1","newsmorepage"
				f_Lable_News_Cont = f_NEWS_CONT_MATCHS(0).Value
				Set f_NEWS_CONT_REPLACE_FLAG_OBJ = New RegExp
				f_NEWS_CONT_REPLACE_FLAG_OBJ.IgnoreCase = True
				f_NEWS_CONT_REPLACE_FLAG_OBJ.Global = True
				f_NEWS_CONT_REPLACE_FLAG_OBJ.Pattern = "\[FS\:CONTENT_START\]"
				f_Lable_News_Cont = f_NEWS_CONT_REPLACE_FLAG_OBJ.Replace(f_Lable_News_Cont,"")
				f_NEWS_CONT_REPLACE_FLAG_OBJ.Pattern = "\[FS\:CONTENT_END\]"
				f_Lable_News_Cont = f_NEWS_CONT_REPLACE_FLAG_OBJ.Replace(f_Lable_News_Cont,"")
				Set f_NEWS_CONT_REPLACE_FLAG_OBJ = Nothing
				f_ARRAY_OBJ = Split(f_Lable_News_Cont,f_DICT_MATCHS(0).Value)
				PageNum_Flag=False
				Str_Other=Split(f_DICT_ITEMS_OBJ(f_i),f_NEWS_CONT_MATCHS(0).Value)
				for f_j = LBound(f_ARRAY_OBJ) To UBound(f_ARRAY_OBJ)
					if Len(f_ARRAY_OBJ(f_j)) > 1 then
						if Not f_MORE_PAGES_DICT_OBJ.Exists(f_j) Then
							f_MORE_PAGES_DICT_OBJ.Add f_j,f_ARRAY_OBJ(f_j)
						End If 
						PageNum_Flag=True
					end if
				Next
				If PageNum_Flag Then
					f_Raw_Data = Replace(f_Raw_Data,f_DICT_KEYS_OBJ(f_i),Str_Other(0)&f_DICT_KEYS_OBJ(f_i)&Str_Other(1))
				End If 
				Set Str_Other=Nothing 
				f_Replace_Flag_TF = True
			end if
			Set f_NEWS_CONT_REG_OBJ = Nothing
			Set f_REG_PLACE_OBJ = Nothing
			if Not f_Replace_Flag_TF Then
				f_DICT_ITEMS_OBJ(f_i)=Replace(f_DICT_ITEMS_OBJ(f_i),"{|}","")
				f_Raw_Data = Replace(f_Raw_Data,f_DICT_KEYS_OBJ(f_i),f_DICT_ITEMS_OBJ(f_i))
			End If
		Else
			f_DICT_ITEMS_OBJ(f_i)=Replace(f_DICT_ITEMS_OBJ(f_i),"{|}","")
			f_Raw_Data = Replace(f_Raw_Data,f_DICT_KEYS_OBJ(f_i),f_DICT_ITEMS_OBJ(f_i))
		End If
	Next
	f_MORE_PAGES_DICT_OBJ.Item("-3") = Replace(f_Raw_Data,"{|}","")
	f_LABLE_DICT_OBJ.RemoveAll
	Set f_LABLE_DICT_OBJ = Nothing
	''Dic_Test(f_DICT_ITEMS_OBJ)
	Set Replace_All_Flag = f_MORE_PAGES_DICT_OBJ
	Set f_MORE_PAGES_DICT_OBJ = Nothing
End Function



Function Get_Templet_Content(Str_Templet_File_Path)
	Dim f_Phy_Templet,f_FSO_OBJ,f_FILE_OBJ,f_FILE_STREAM_OBJ
	If Request.Cookies("FoosunMFCookies")="" Or Request.Cookies("FoosunMFCookies")=Empty Then MFConfig_Cookies
	If Request.Cookies("FoosunNSCookies")="" Or Request.Cookies("FoosunNSCookies")=Empty Then NSConfig_Cookies
	If Request.Cookies("FoosunDSCookies")="" Or Request.Cookies("FoosunDSCookies")=Empty Then DSConfig_Cookies
	If Request.Cookies("FoosunMSCookies")="" Or Request.Cookies("FoosunMSCookies")=Empty Then
		if IsExist_SubSys("MS") then MSConfig_Cookies
	End If
	If Str_Templet_File_Path<>"" Then
		f_Phy_Templet = Server.MapPath(Str_Templet_File_Path)
		Set f_FSO_OBJ = Server.CreateObject(G_FS_FSO)
		if f_FSO_OBJ.FileExists(f_Phy_Templet) = False then
			Get_Templet_Content = "模板不存在，请添加模板后再生成！"
		else
			Set f_FILE_OBJ = f_FSO_OBJ.GetFile(f_Phy_Templet)
			Set f_FILE_STREAM_OBJ = f_FILE_OBJ.OpenAsTextStream(1)
			if Not f_FILE_STREAM_OBJ.AtEndOfStream then
				Get_Templet_Content = f_FILE_STREAM_OBJ.ReadAll
			else
				Get_Templet_Content = "模板内容为空"
			end if
		end if
		'Get_Templet_Content = Get_Templet_Content & Get_JS_CopyRight("NewsID")
		Set f_FILE_STREAM_OBJ = Nothing
		Set f_FILE_OBJ = Nothing
		Set f_FSO_OBJ = Nothing
	Else
		Get_Templet_Content="模板不存在，请添加模板后再生成！"
	End If
End Function

Function Get_Dynamic_Refresh_Content(Str_Templet,Str_GoID,sysFlag,Page,PageType)
	Dim f_PAGES_DICT_OBJ,f_Temf_File_Content,f_MORE_PAGES_DICT_ITEMS_OBJ,f_MORE_PAGES_DICT_KEYS_OBJ,f_More_Page_Link_Str
	Dim f_i,int_count,f_PLACE_OBJ,f_Temp_More_Page_Link_Str,f_More_Page_Array,f_File_Content,Str_Page_Style
	Dim patrn(1),strng
	patrn(0)="</head>"
	patrn(1)="<body"
	strng=Get_JS_CopyRight("NewsId")
	If VarType(Page)<>2 Then
		Page=1
	ElseIf Page<1 Then
		Page=1
	End If
	Set f_PAGES_DICT_OBJ = Replace_All_Flag(Get_Templet_Content(Str_Templet),Str_GoID,sysFlag,PageType)
	f_File_Content = f_PAGES_DICT_OBJ.Item("-3")
	f_MORE_PAGES_DICT_ITEMS_OBJ = f_PAGES_DICT_OBJ.Items
	f_MORE_PAGES_DICT_KEYS_OBJ = f_PAGES_DICT_OBJ.Keys
	Rem 建立正则对象
	Set f_PLACE_OBJ = New RegExp
	Rem ============
	if f_PAGES_DICT_OBJ.Count > 3 then
		int_count=1
		for f_i = 3 to f_PAGES_DICT_OBJ.Count - 1
			f_More_Page_Link_Str = f_PAGES_DICT_OBJ.Item("-1")
			If Page>f_PAGES_DICT_OBJ.Count - 3 Then
				Page=f_PAGES_DICT_OBJ.Count - 3
			End If
			If f_More_Page_Link_Str = "newsmorepage" Then
				f_More_Page_Link_Str = Get_More_Page_Link_Str("","","",f_PAGES_DICT_OBJ.Count - 3,Page)
			Else
				f_PLACE_OBJ.Pattern = "{Foosun_Page_news}"
				f_PLACE_OBJ.IgnoreCase = True
				f_PLACE_OBJ.Global = True
				f_Temp_More_Page_Link_Str = f_PLACE_OBJ.Replace(f_More_Page_Link_Str,"")
				f_PLACE_OBJ.Pattern = "{/Foosun_Page_news}"
				f_Temp_More_Page_Link_Str = f_PLACE_OBJ.Replace(f_Temp_More_Page_Link_Str,"")
				f_More_Page_Array = Split(f_Temp_More_Page_Link_Str,",")
				Str_Page_Style=Split(f_More_Page_Array(1),"|")
				if UBound(f_More_Page_Array) < 1 then
					f_More_Page_Link_Str = ""
				else
					f_More_Page_Link_Str = Get_More_Page_Link_Str(Trim(f_More_Page_Array(0)),Trim(Str_Page_Style(0)),Trim(Str_Page_Style(1)),f_PAGES_DICT_OBJ.Count - 3,Page)
				end if
			end If
			If Page>0 And int_count=Page Then
				f_Temf_File_Content = Replace(f_File_Content,f_PAGES_DICT_OBJ.Item("-2"),f_MORE_PAGES_DICT_ITEMS_OBJ(f_i) & f_More_Page_Link_Str)
				Exit For
			End If
			int_count=int_count+1
		Next
	Else
		f_Temf_File_Content = f_File_Content
	End If
	Rem 加入版权信息和关键JS文件（正则搜索）
	f_PLACE_OBJ.Pattern = patrn(0)
	f_PLACE_OBJ.IgnoreCase = True
	f_PLACE_OBJ.Global = False
	f_PLACE_OBJ.Multiline = True
	If f_PLACE_OBJ.Test(f_Temf_File_Content) Then
		f_Temf_File_Content=f_PLACE_OBJ.Replace(f_Temf_File_Content,patrn(0)&vbNewLine&strng)
	Else
		f_PLACE_OBJ.Pattern = patrn(1)
		If f_PLACE_OBJ.Test(f_Temf_File_Content) Then
			f_Temf_File_Content=f_PLACE_OBJ.Replace(f_Temf_File_Content,patrn(1)&vbNewLine&strng)
		Else
			f_Temf_File_Content=strng&vbNewLine&f_Temf_File_Content
		End If
	End If
	Rem ===================================
	Set f_PLACE_OBJ = Nothing
	Get_Dynamic_Refresh_Content=f_Temf_File_Content
	f_PAGES_DICT_OBJ.RemoveAll
	Set f_PAGES_DICT_OBJ = Nothing
End Function

Function Get_More_Page_Link_Str(f_More_Page_Link_Type,f_More_Page_Link_Color,f_More_Page_Css,f_Page_Count,f_More_Page_Index)
	Dim f_i,Str_Link,LinkUrl,Str_Style
	Dim str_nonLinkColor,str_toF,str_toP10,str_toP1,str_toN1,str_toN10,str_toL,StartPage,EndPage,I
	If f_More_Page_Index>f_Page_Count Then
		f_More_Page_Index=f_Page_Count
	End If
	If f_More_Page_Link_Type="" Then
		f_More_Page_Link_Type=0
	End If
	Str_Link=""
	LinkUrl = ThisPageUrl("page","submit")
	Str_Style=""
	If f_More_Page_Link_Color<>"" Then
		Str_Style=Str_Style&" style=""color: #"&f_More_Page_Link_Color&";"""
	End If
	If f_More_Page_Css<>"" Then
		Str_Style=Str_Style&" class="""&f_More_Page_Css&""""
	End If

	If f_Page_Count>1 Then
		Select Case f_More_Page_Link_Type
			Case 1
				If f_More_Page_Index=1 Then
					Str_Link=Str_Link&"上一页"
					Str_Link=Str_Link&"&nbsp;<a href="""&LinkUrl&f_More_Page_Index+1&""""&Str_Style&">下一页</a>"
				ElseIf (f_More_Page_Index+1)>f_Page_Count Then
					Str_Link=Str_Link&"<a href="""&LinkUrl&f_More_Page_Index-1&""""&Str_Style&">上一页</a>"
					Str_Link=Str_Link&"&nbsp;下一页"
				Else
					Str_Link=Str_Link&"<a href="""&LinkUrl&f_More_Page_Index-1&""""&Str_Style&">上一页</a>"
					Str_Link=Str_Link&"&nbsp;<a href="""&LinkUrl&f_More_Page_Index+1&""""&Str_Style&">下一页</a>"
				End If
			Case 2
				Str_Link="共"&f_Page_Count&"页，"
				For f_i=1 To f_Page_Count
					If f_i= f_More_Page_Index Then
						Str_Link=Str_Link&",第"&f_i&"页"
					Else
						Str_Link=Str_Link&",<a href="""&LinkUrl&f_i&""""&Str_Style&">第"&f_i&"页</a>"
					End If
				Next
			Case 3
				Str_Link="共"&f_Page_Count&"页。"
				For f_i=1 To f_Page_Count
					If f_i= f_More_Page_Index Then
						Str_Link=Str_Link&"&nbsp;"&f_i&""
					Else
						Str_Link=Str_Link&"&nbsp;<a href="""&LinkUrl&f_i&""""&Str_Style&">"&f_i&"</a>"
					End If
				Next
			Case Else
				str_nonLinkColor="#999999" '非热链接颜色
				str_toF="<font face=""webdings"">9</font>"  			'首页
				str_toP10="<font face=""webdings"">7</font>"			'上十
				str_toP1="<font face=""webdings"">3</font>"				'上一
				str_toN1="<font face=""webdings"">4</font>"				'下一
				str_toN10="<font face=""webdings"">8</font>"			'下十
				str_toL="<font face=""webdings"">:</font>"				'尾页

				Str_Link=""

				if f_More_Page_Index=1 then
					Str_Link=Str_Link& "<font color="&str_nonLinkColor&" title=""首页"">"&str_toF&"</font> " &vbNewLine
				Else
					Str_Link=Str_Link& "<a href="""&LinkUrl&"1"""&Str_Style&" title=""首页"">"&str_toF&"</a> " &vbNewLine
				End If
				if f_More_Page_Index<11 then
					StartPage = 1
				else
					If f_More_Page_Index>(fix(f_More_Page_Index / 10) * 10) Then
						StartPage = (fix(f_More_Page_Index / 10) * 10)+1
					Else
						StartPage = ((fix(f_More_Page_Index / 10)-1) * 10)+1
					End If
				end if
				EndPage=StartPage+9
				If EndPage>f_Page_Count Then
					EndPage=f_Page_Count
				End If

				If StartPage>10 Then
					Str_Link=Str_Link& "<a href="""&LinkUrl&f_More_Page_Index-10&""""&Str_Style&" title=""上10页"">"&str_toP10&"</a> "  &vbNewLine
				Else
					Str_Link=Str_Link& "<font color="&str_nonLinkColor&" title=""上10页"">"&str_toP10&"</font> "  &vbNewLine
				End If

				If f_More_Page_Index > 1 Then
					Str_Link=Str_Link& "<a href="""&LinkUrl&f_More_Page_Index-1&""""&Str_Style&" title=""上一页"">"&str_toP1&"</a> "  &vbNewLine
				Else
					Str_Link=Str_Link& "<font color="&str_nonLinkColor&" title=""上一页"">"&str_toP1&"</font> "  &vbNewLine
				End If

				For I=StartPage To EndPage
					If I=f_More_Page_Index Then
						Str_Link=Str_Link& "<b>"&I&"</b>"  &vbNewLine
					Else
						Str_Link=Str_Link& "<a href="""&LinkUrl&I&""""&Str_Style&">" &I& "</a>"  &vbNewLine
					End If
				Next
				If f_More_Page_Index < f_Page_Count Then
					Str_Link=Str_Link& " <a href="""&LinkUrl&f_More_Page_Index+1&""""&Str_Style&" title=""下一页"">"&str_toN1&"</a> "  &vbNewLine
				Else
					Str_Link=Str_Link& "<font color="&str_nonLinkColor&" title=""下一页"">"&str_toN1&"</font> "  &vbNewLine
				End If

				If EndPage<f_Page_Count Then
					If (f_More_Page_Index+10)>f_Page_Count Then
						Str_Link=Str_Link& " <a href="""&LinkUrl&f_Page_Count&""""&Str_Style&"  title=""下10页"">"&str_toN10&"</a> "  &vbNewLine
					Else
						Str_Link=Str_Link& " <a href="""&LinkUrl&f_More_Page_Index+10&""""&Str_Style&" title=""下10页"">"&str_toN10&"</a> "  &vbNewLine
					End If
				Else
					Str_Link=Str_Link& " <font color="&str_nonLinkColor&"  title=""下10页"">"&str_toN10&"</font> "  &vbNewLine
				End If

				if f_More_Page_Index<f_Page_Count Then
					Str_Link=Str_Link& "<a href="""&LinkUrl&f_Page_Count&""""&Str_Style&" title=""尾页"">"&str_toL&"</a>"  &vbNewLine
				Else
					Str_Link=Str_Link& "<font color="&str_nonLinkColor&" title=""尾页"">"&str_toL&"</font>"  &vbNewLine
				End If
		End Select
	End If
	Get_More_Page_Link_Str="<div>"&Str_Link&"</div>"
End Function

'*********************************************************
' 目的：分页的页面参数保持
'          提交查询的一致性
' 输入：moveParam：分页参数
'         removeList：要移除的参数
' 返回：分页Url
'*********************************************************
Function ThisPageUrl(moveParam,removeList)
	dim strName
	dim KeepUrl,KeepForm,KeepMove
	removeList=removeList&","&moveParam
	KeepForm=""
	For Each strName in Request.Form
		'判断form参数中的submit、空值
		if not InstrRev(","&removeList&",",","&strName&",", -1, 1)>0 and Request.Form(strName)<>"" then
			KeepForm=KeepForm&"&"&strName&"="&Server.URLencode(Request.Form(strName))
		end if
		removeList=removeList&","&strName
	Next

	KeepUrl=""
	For Each strName In Request.QueryString
		If not (InstrRev(","&removeList&",",","&strName&",", -1, 1)>0) Then
			KeepUrl = KeepUrl & "&" & strName & "=" & Server.URLencode(Request.QueryString(strName))
		End If
	Next

	KeepMove=KeepForm&KeepUrl

	If (KeepMove <> "") Then
	  KeepMove = Right(KeepMove, Len(KeepMove) - 1)
	  KeepMove = Server.HTMLEncode(KeepMove) & "&"
	End If

	ThisPageUrl = Request.ServerVariables("URL") & "?" & KeepMove & moveParam & "="
End Function
Function Get_JS_CopyRight(f_type)
	Get_JS_CopyRight = "<script language=""JavaScript"" src=""http://" & Get_MF_Domain & "/FS_Inc/Prototype.js""></script>" & vbNewLine
	Get_JS_CopyRight = Get_JS_CopyRight & "<!--Created Page at " & Now() & ",by Foosun.Cn,Foosun Content Management System 4.0.0(FoosunCMS)--> "
End Function
%>