<!--#include file="md5char.asp"-->
<!--#include file="paysettings.asp"-->
<%
'#############################################################
'#               贺喜支付平台支付接口接收程序
'#                            v1.5
'#                   http://www.168reg.cn
'#
'#  版权所有: 株洲市和谐网络科技发展有限公司
'#
'#  主页地址: http://www.168reg.cn
'#  技术支持: support@168reg.cn
'#  技 术 QQ: 359465724
'#  技术QQ群：7048987
'#
'#############################################################
'# ·郑重声明:
'# ·此程序不得随意公开发布、销售或进行其他非法转让。
'# ·如对此程序有任何疑问，请在管理区留言。
'#############################################################
'您可以充分利用以下反馈信息并添加到您自己的数据库中。
vip=Request.ServerVariables("Remote_Addr")   '提交者IP地址
v_orderid=Request.Form("v_orderid")   '贺喜支付平台反馈的定单号
v_orderdate=Request.Form("v_orderdate")   '定单成交时间
v_price=Request.Form("v_price")   '定单成交价格，以分为单位
v_billno=Request.Form("v_billno")   '商户订单号
v_custom1=Request.Form("v_custom1")   '自定义字段1
v_custom2=Request.Form("v_custom2")   '自定义字段2
v_mobileno=Request.Form("v_mobileno")   '用户支付的手机号码
v_servicename=Request.Form("v_servicename")   '支付订单的服务名称
v_payvia=Request.Form("v_payvia")   '用户选择的支付途径，1：银行卡在线支付；2：声讯电话支付；3：互联星空支付；4：手机短信注册；5，腾讯财付通支付；6，腾讯Q币支付
v_md5=Request.Form("v_md5")   '返回的加密字符串
v_pstatus=Request.Form("v_pstatus")   '定单成功反馈的字符串，有1和0两种情况。主要用于验证是否属正常反馈。
v_pstring=Request.Form("v_pstring")   '定单支付状态说明。
v_paymode=Request.Form("v_paymode")   '当前定单运行模式，仅启用测试模式时有效，值为testmode。

if v_pstatus="1" then
if v_orderid="" or v_orderdate="" or v_price="" or v_md5="" or v_payvia="" then%>
<script language=vbscript>
  MsgBox "非法反馈：反馈的数据不正确！"
  location.href = "/"
</script>
<%Response.end
end if
'以下程序验证返回的加密字符串是否正确
encrypt_string=Ucase(trim(md5(v_orderid&v_billno&v_custom1&v_custom2&v_price&v_payvia&reg_userid&v_pstatus&paykey&v_paymode)))
if v_md5<>encrypt_string then%>
<script language=vbscript>
  MsgBox "致命错误：返回的加密字符串不正确，您是非法提交！"
  location.href = "/"
</script>
<%Response.end
end if
'验证返回的加密字符串是否正确程序结束

'以下程序防止用户是否多次刷新成功页面，最好的方法是您做成从自己的数据库中检测v_orderid定单号是否已成交，如果已成交，就不显示页面。
if session("reg168_orderid")<>"" then
	if session("reg168_orderid")=v_orderid then%>
	<script language=vbscript>
	  MsgBox "错误：同一定单成交页面不允许多次刷新或提交！"
	  location.href = "/"
	</script>
	<%Response.end
	else
		session("reg168_orderid")=v_orderid
	end if
else
	session("reg168_orderid")=v_orderid
end if
'为防止用户多次刷新成功页面，使缓存的页面立即过期
Response.Expires=0

'贺喜支付平台强烈推荐您进行定单号验证，如果觉得定单可疑，请到定单管理区核对。因为贵站安全措施未做好而造成的损失，贺喜支付平台概不负责。


'将订单支付金额换成以元为单位
payfee=FormatNumber(v_price/100,2,True)

'判断用户使用何支付途径支付
select case v_payvia
	case 1
		payviastr="银行卡在线支付"
	case 2
		payviastr="声讯电话支付"
	case 3
		payviastr="互联星空支付"
	case 4
		payviastr="手机短信注册"
	case 5
		payviastr="腾讯财付通支付"
	case 6
		payviastr="腾讯Q币支付"
end select

'下面请放入定单成功页面的HTML代码，可自定义%>
<HTML><HEAD>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<MEAT HTTP-EQUIV="Pragma" CONTENT="no-cache">
<TITLE>定单成交信息</TITLE>
</HEAD>
<BODY>
<p>您已经成功支付！</p>
<p>
支付金额：<%=payfee%> 元<br>
贺喜支付平台订单号：<%=v_orderid%><br>
支付途径：<%=payviastr%><br>
付款状态：<%=v_pstatus%><br>
付款状态说明：<%=v_pstring%><br>
IP地址：<%=vip%><br>
订单成交时间：<%=v_orderdate%><br>
商户订单号：<%=v_billno%><br>
自定义字段1：<%=v_custom1%><br>
自定义字段2：<%=v_custom2%><br>
<%
'用户选择手机短信注册时将返回手机号码
if v_payvia=4 then
	response.write "用户手机号码：" & v_mobileno & "<br>"
end if
%>
服务名称：<%=v_servicename%><br>
返回的加密字符串：<%=v_md5%><br>
<%if v_paymode="testmode" then%>运行模式：测试模式<%end if%>
</p>
</BODY></HTML>
<%else
'下面请放入定单失败页面的HTML代码%>
<HTML><HEAD>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<TITLE>定单支付失败</TITLE>
</HEAD>
<BODY>
<p>
定单支付失败
</p>
</BODY></HTML>
<%end if%></body></html>