﻿
<%
dim conn,connstr,db
db="conn/article.mdb"
Set conn = Server.CreateObject("ADODB.Connection")
connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(""&db&"") &";Jet OLEDB:DataBase Password='huaxiaoxing'"
conn.Open connstr
'====================================================================================================
'作用  删除记录  
'参数  talname 表名
'参数  id 
'====================================================================================================
Sub del_id(talname)
dim rs_d,id
id=getPost("id",true)
if id="" or not isnumeric(id) then
       response.Write(response_error("参数错误",2,""))
       response.End()
else
id=int(id)	   
end if
set rs_d=server.CreateObject("adodb.recordset")
    rs_d.Open "select id from "& talname &" where id="&id ,conn,1,3
	   if rs_d.eof then
       response.Write(response_error("没有记录",2,""))
       response.End()
	   end if
	   rs_d.delete
       response.Write(response_error("删除成功",2,""))
       response.End()
rs_d.close
set rs_d=nothing
end sub
'====================================================================================================
'作用  返回错误  
'参数  str 错误类型
'参数  lei 类型   （1  关闭  |   2  返回上一页  |  3  打开网址  ）
'参数  local 网址
'====================================================================================================
Function  response_error(str,lei,local)
dim response_errorstr : response_errorstr=""
response_errorstr = response_errorstr & "<script language=""javascript"">window.alert("""& str &""");"
if lei=1 then
response_errorstr = response_errorstr & "window.close(); "
elseif lei=2 then
response_errorstr = response_errorstr & "history.go(-1); "
elseif lei=3 then
response_errorstr = response_errorstr & "window.location.href ="""& local &"""; "
end if
response_errorstr = response_errorstr & "</script> " 
response_error=response_errorstr
end function


'====================================================================================================
'作用  返回错误  
'参数  str 错误类型
'参数  lei 类型   （1  关闭  |   2  返回上一页  |  3  打开网址  ）
'参数  local 网址
'====================================================================================================
Sub rps_error(str,lei,local)
response.Write("<meta http-equiv=""Content-Type"" content=""text/html""; charset=""UTF-8"">"& vbcrlf)
response.Write("<script language=""javascript"">"& vbcrlf)
response.Write("<!--"& vbcrlf)
response.Write("window.alert("""& str &""");"& vbcrlf)
     if lei=1 then
     response.Write("window.opener=null; "& vbcrlf)
     response.Write("window.close(); "& vbcrlf)
     elseif lei=2 then
     response.Write("window.location.href ="""& request.ServerVariables("HTTP_REFERER") &"""; "& vbcrlf)
     elseif lei=3 then
     response.Write("window.location.href ="""& local &"""; "& vbcrlf)
     end if
response.Write("//-->"& vbcrlf)
response.Write("</script>") 
end Sub


'====================================================================================================
'作用   取得表单值
'参数   var 字段名字
'参数   is_sql  是否加入SQL防注入
'====================================================================================================
	Function getPost(var,is_sql)
	dim val:val=""
		val = Trim(Request.Form(var))
		If val = "" Then
			val = Trim(Request.QueryString(var))
		End If
		if is_sql=false then
		getPost = val
		else
		getPost = val
		end if 
	End Function
'====================================================================================================================================
'作用：显示分页连接
'参数：curpage 当前页次
'参数：pagetotal  总页次
'参数：pageNUM  每页显示记录
'参数：total 总记录数
'参数：filename 文件名
'====================================================================================================================================
function showpage(curpage,pagetotal,pageNUM,total,filename)
dim showpagestr
showpagestr=""
			'showpagestr = showpagestr &"<form method=Post name='yeform' action="""& filename &""">"
			if curpage<>1 then
			showpagestr = showpagestr &"<a href='"& filename &"curpage=1' >首页</a>"
			else
			showpagestr = showpagestr &"首页"
			end if
			showpagestr = showpagestr &"&nbsp;|&nbsp;"
			
			if curpage>1 then
			showpagestr = showpagestr &"<a href='"& filename &"curpage="& int(curpage-1) &"' >前一页</a>"
			else
			showpagestr = showpagestr &"前一页"
			end if
			showpagestr = showpagestr &"&nbsp;|&nbsp;"

			if curpage<pagetotal then
			showpagestr = showpagestr &"<a href='"& filename &"curpage="& int(curpage+1) &"' >后一页</a>"
			else
			showpagestr = showpagestr &"后一页"
			end if
			showpagestr = showpagestr &"&nbsp;|&nbsp;"

			if curpage<>pagetotal then
			showpagestr = showpagestr &"<a href='"& filename &"curpage="& pagetotal &"' >尾页</a>"
			else
			showpagestr = showpagestr &"尾页"
			end if
			showpagestr = showpagestr &"&nbsp;|&nbsp;"
			showpagestr = showpagestr &"当前为 <font color=red >"& curpage &"</font>/"& pagetotal &"页 每页"& pageNUM &"项 总共<font color=red >"& total &"</font>条记录"
			showpagestr = showpagestr &"&nbsp;&nbsp;转到：&nbsp;<select name='curpage' size='1' onchange=""javascript:window.location='"& filename &"curpage='+this.options[this.selectedIndex].value;"">"
			dim g
			for g=1 to pagetotal
			showpagestr = showpagestr &"<option value='"& g &"' "
			     if g=curpage then
				 showpagestr = showpagestr &" selected "
				 end if 
			showpagestr = showpagestr &">第"& g &"页</option>"
			next
			showpagestr = showpagestr &"</select>"			
			
showpage=showpagestr			
end function
'====================================================================================================
'作用   关闭数据库
'参数   无
'====================================================================================================
sub closeconn()
conn.close
set conn=nothing
end sub

Function get_ty(tableName,Selectid,typ)
	Dim get_tyStr : get_tyStr=""
	Dim Sql : Sql="Select * from ["& tableName &"] "
	Dim rw
	if typ=1 then
		set rw=conn.execute(Sql &" where id="& Selectid )
			if rw.eof then
				get_tyStr="没有记录"
			else
				get_tyStr=rw("nr")
			end if	
	elseif typ=2 then
		set rw=conn.execute(Sql &" order by orderby asc ")
			if rw.eof then
				get_tyStr="没有记录"
			else
				do while not rw.eof
					get_tyStr=get_tyStr &"<option value="""& rw("id") &""" "
					if Cstr(Selectid)=Cstr(rw("id")) then
						get_tyStr=get_tyStr &" Selected "
					end if
					get_tyStr=get_tyStr &">"& rw("nr") &"</option>"& vbcrlf
				rw.movenext
				loop
			end if
	end if
	set rw=nothing
	get_ty=get_tyStr
end function

%>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
