<!-- #include file="include/skin.asp" -->
<!-- #include file="include/jk_email.asp" -->
<!-- #include file="include/jk_sendmail.asp" -->
<!-- #include file="include/jk_val_code.asp" -->
<%
tit="查看投票信息"
call web_head(0,0,4,0,0)
response.write vbcrlf&joekoe_cms.js_put("self.moveTo(0,0);",1)
response.write vbcrlf&"<table cellspacing=1 cellpadding=4 class=table>"
response.write vbcrlf&"<tr><td class=td0 colspan=2>&nbsp;"&img_skin("m_")&tit&"</td></tr>"

if login_mode="" then
  response.write "<script language=javascript>alert(""您现在还没有登陆本站！\n\n请先注册并登陆本站。"");window.close();</script>"
else
  call vote_user_main()
end if

response.write vbcrlf&"</table>"
call web_copy()
call web_end(0,1)

sub vote_user_main()
  dim viewid,topic,tim,vote_num,v_username,vdim,vnum,tdim,tnum,ti
  viewid=trim(request.querystring("view_id"))
  if not int_true(viewid) then
    response.write "<script language=javascript>alert(""查看调查信息的ID出错！\n\n请勿非法提交参数！"");window.close();</script>"
    exit sub
  end if
  sql="select top 1 t.topic,t.tim,t.vote_num,v.v_username from bbs_topic as t,bbs_vote as v where t.isvote=1 and t.id="&viewid&" and v.reply_id="&viewid
  set rs=joekoe_cms.exec(sql,1)
  if rs.eof then
    rs.close
    response.write "<script language=javascript>alert(""查看调查信息的ID出错！\n\n请勿非法提交参数！"");window.close();</script>"
    exit sub
  end if
  topic=rs("topic")
  tim=rs("tim")
  vote_num=rs("vote_num")
  v_username=rs("v_username")
  rs.close
%>
<tr class=bg_tds><td colspan=2 align=center class=htd><font class=blue><b><%response.write joekoe_cms.code_html(topic,1,0)%></b></font></td></tr>
<tr class=bg_tds><td colspan=2 align=center class=htd><font class=gray>共<font class=red><%response.write vote_num%></font>票，发起时间：<font alt='<%response.write joekoe_cms.time_type(tim,2)%>'><%response.write joekoe_cms.time_type(tim,4)%></font></font></td></tr>
<%
  vdim=split(v_username,"|")
  vnum=ubound(vdim)
  for i=0 to vnum
%>
<tr class=bg_td>
<td><%response.write format_user_name(left(vdim(i),instr(vdim(i),":")-1),0,"")%></td>
<td><%
    tdim=split(right(vdim(i),len(vdim(i))-instr(vdim(i),":")),",")
    tnum=ubound(tdim)
    for ti=0 to tnum
      response.write tdim(ti)+1
      if ti<tnum then response.write ","
    next
    erase tdim
%></td>
</tr>
<%
  next
  erase vdim
end sub
%>