<!--#include file="conn.asp"-->
<%
'-------------------------------------
'功能：处理点出的程序
'更新：2004-12-27 19:02
'作者：未知-部落忍者
'演示：http://www.0cc.cn/link/
'-------------------------------------

dim username,comeurl
username=hx.checkstr(request("username"),12)
if username="" then
CloseDatabase
Response.write "用户名有误"
Response.End
end if
comeurl=hx.checkstr(Request.ServerVariables("http_referer"),200)

dim rs,sql
dim siteurl
set rs=server.createobject("adodb.recordset")
sql="select TOP 1 siteurl,outc,outj,outp,outdate,fromdate from CL_Link where username='"&username&"'"
rs.open sql,conn,1,2
if not rs.eof then
	siteurl=rs("siteurl")
	if left(siteurl,7)<>"http://" then siteurl="http://" & siteurl
	If comeurl<>"" and not hx.isrec(1) then
		rs("outc")=rs("outc")+1
		if DateDiff("d",rs("outdate"),Date())=0 then
			rs("outj")=rs("outj")+1
		else
			rs("outj")=1
		end if
		rs("outdate")=Now()
		rs.update
		rs("outp")=rs("outc")/(DateDiff("d",rs("fromdate"),Date())+1)
		rs.update
	end if
		
else
   siteurl=WebUrl
end if
rs.close
set rs=nothing

CloseDatabase
Response.Redirect siteurl
%>