<!-- #include file="../../include/skin.asp" -->
<%
dim md_left,md_center,md_more,md_end,md_view
md_left=39:md_center=40:md_more=41:md_end=42:md_view=43
%>
<!-- #include file="../../include/jk_nsort.asp" -->
<!-- #include file="../../style/data_sort_art.asp" -->

<%
cid=0
sid=0
n_sort="art"
index_url="article"
tit_fir=format_menu(index_url)
m_channel=index_url
web_img_m="m_"&m_channel
web_img_h="h_"&m_channel

'================================================
'作    用：清除变量
'================================================
sub article_end()
  if isarray(sort_dim) then erase sort_dim
  if CMS_skend then
  CMS_Skin_Mod.sk_end
  set CMS_Skin_Mod=nothing
  end if
end sub

'================================================
'作    用：文章左边部分功能模块
'参    数：
'  nt        ：判断文章的类型，如热门文章、推荐文章等
'  n_num     ：每个模块显示文章标题数
'  c_num     ：文章标题字数
'  n_title   ：模块名称
'================================================
sub article_left(nt,n_num,c_num,n_title)
  dim n_username,n_topic,n_tim,tmp
  sql="select top "&n_num&" id,username,topic,tim,counter,emoney,power,tcolor from article where hidden=1"
  select case nt
  case "hot"
    sql=sql&" order by counter desc,id desc"
  case "good"
    sql=sql&" and istop=1 order by id desc"
  case else
    sql=sql&" order by id desc"
  end select
  set rs=joekoe_cms.exec(sql,1)
  do while not rs.eof
    n_username=rs("username")
    n_topic=rs("topic")
    n_tim=rs("tim")
    n_tim=joekoe_cms.time_type(n_tim,1)
    tmp=tmp&article_topic_type(c_num,rs("id"),n_username,n_topic,n_tim,rs("counter"),false,0,rs("emoney"),rs("power"),rs("tcolor"))
    rs.movenext
  loop
  rs.close
  tmp="<table border=0 width='100%'>"&tmp&"</table>"
  call article_bar_top_left(n_title,tmp)
end sub

sub article_left2(nt,c_id,s_id,n_num,c_num,n_title)
  dim n_username,n_topic,n_tim,tmp
  sql="select top "&n_num&" id,username,topic,tim,counter,emoney,power,tcolor from article where hidden=1"
  if s_id<1 then
  sql=sql&" and c_id="&c_id
  else
  sql=sql&" and c_id="&c_id&" and s_id="&s_id
  end if
  select case nt
  case "hot"
    sql=sql&" order by counter desc,id desc"
  case "good"
    sql=sql&" and istop=1 order by id desc"
  case else
    sql=sql&" order by id desc"
  end select
  set rs=joekoe_cms.exec(sql,1)
  do while not rs.eof
    n_username=rs("username")
    n_topic=rs("topic")
    n_tim=rs("tim")
    n_tim=joekoe_cms.time_type(n_tim,1)
    tmp=tmp&article_topic_type(c_num,rs("id"),n_username,n_topic,n_tim,rs("counter"),false,0,rs("emoney"),rs("power"),rs("tcolor"))
    rs.movenext
  loop
  rs.close
  tmp="<table border=0 width='100%'>"&tmp&"</table>"
  call article_bar_top_left(n_title,tmp)
end sub

'作    用：文章分类
sub article_left_sort(nsn,ntt)
  dim tmp1,surl,body
  surl="list.asp?action=more&"
  tmp1=article_label_list()&vbcrlf&nsort_left_type(surl,ntt)
  call article_bar_top_left(nsn,tmp1) 
end sub

'================================================
'作    用：文章各模块显示模式功能模块
'参    数：
'  tit       ：模块名称
'  body      ：模块内容
'================================================
Sub article_bar_top(tit,body,tmore)
  dim tmp,more_var
  if var_null(tmore)<>"" then
  more_var=cms_skin.md(md_more)
  more_var=replace(more_var,"{$url}",tmore)
  else
  more_var=""
  end if
  tmp=cms_skin.md(md_center)
  tmp=Replace(tmp,"{$web_skin}",joekoe_cms.web_dir_skin)
  tmp=Replace(tmp,"{$img}",img_skin(web_img_m))
  tmp=Replace(tmp,"{$tit}",tit)
  tmp=Replace(tmp,"{$body}",body)
  tmp=Replace(tmp,"{$more}",more_var)
  tmp=Replace(tmp,"{$ukong}",CMS_Skin.skukong)
  Response.Write (Vbcrlf&tmp)
end Sub

Sub article_bar_top_left(tit,body)
  dim tmp
  tmp=cms_skin.md(md_left)
  tmp=Replace(tmp,"{$web_skin}",joekoe_cms.web_dir_skin)
  tmp=Replace(tmp,"{$img}",img_skin(web_img_m))
  tmp=Replace(tmp,"{$tit}",tit)
  tmp=Replace(tmp,"{$body}",body)
  tmp=Replace(tmp,"{$ukong}",CMS_Skin.skukong)
  Response.Write (Vbcrlf&tmp)
end Sub
'================================================
'作    用：文章标题显示功能模块
'================================================
function article_topic_type(b_c_num,b_id,b_username,b_topic,b_tim,b_counter,b_ispic,b_tim_type,b_emoney,b_power,tcolor)
  dim n_url,n_jt
  n_url="view.asp?id="&b_id
  n_jt=img_skin(web_img_h)
  article_topic_type=format_article_topic_type(n_jt,b_username,b_topic,b_c_num,n_url,b_tim,b_counter,b_ispic,"文章标题","阅读次数",b_tim_type,b_emoney,b_power,tcolor)
end function

'================================================
'作    用：文章标题显示模式功能模块
'================================================
function format_article_topic_type(b_jt,b_username,b_topic,b_c_num,b_url,b_tim,b_counter,b_ispic,b_tit,b_count,b_tim_type,b_emoney,b_power,tcolor)
  dim n_img,tim_type,n_c_num
  n_c_num=b_c_num
  if b_ispic then
    n_img="&nbsp;<img src='"&joekoe_cms.web_dir_skin&"small/img.gif' border=0>"
    n_c_num=n_c_num-2
  end if
  if b_tim_type>0 then
    if b_tim_type=2 then tim_type=tim_type&"</td><td align=right>"
    tim_type=tim_type&"&nbsp;<font class=tims>"&mid(b_tim,6,5)&"</font>"
  end if
  if var_null(tcolor)<>"" then tcolor="style=""color:"&tcolor&";""" 

  format_article_topic_type="<tr><td>"&b_jt&"<a href='"&b_url&"' "&tcolor&" alt='"&b_tit&"："&joekoe_cms.code_html(b_topic,1,0)&"<br>发 布 人："&b_username&"<br>"&b_count&"："&b_counter&" 人次<br>整理时间："&b_tim&"'>"&joekoe_cms.code_html(b_topic,1,n_c_num)&"</a>"&n_img&tim_type&"</td></tr>"
end function

'================================================
'作    用：文章部分功能链接模块
'================================================
function article_label_list()
  dim temp1
  temp1=temp1&vbcrlf&"<table border=0 cellspacing=0 cellpadding=3 width='100%'>" & _
              vbcrlf&"<tr><td>"&img_skin("sort_s1")&"<a href='list.asp?action=good'"
  if action="good" then temp1=temp1&" class=red"
  temp1=temp1&"><b>推荐文章</b></a></td></tr>" & _
        vbcrlf&"<tr><td>"&img_skin("sort_s1")&"<a href='list.asp?action=hot'"
  if action="hot" then temp1=temp1&" class=red"
  temp1=temp1&"><b>热门文章</b></a></td></tr>" & _
        vbcrlf&"</table>"
  article_label_list=temp1
end function

'================================================
'作    用：文章分页功能模块
'================================================
function article_list_pagecute(p_nummer,p_rssum,p_viewpage,p_thepages,p_pageurl)
  dim temp1
  temp1=temp1&vbcrlf&"<table border=0 width='98%' cellspacing=0 cellpadding=2>" & _
             vbcrlf&"<tr>" & _
             vbcrlf&"<td height=25>" & _
             vbcrlf&"&nbsp;本栏共有 <font class=red>"&p_rssum&"</font> 篇文章" & _
             vbcrlf&"页次：<font class=red>"&p_viewpage&"</font>/<font class=red>"&p_thepages&"</font>&nbsp;" & _
             vbcrlf&"&nbsp;分页："&jk_pagecute(p_nummer,p_thepages,p_viewpage,p_pageurl,5,"#ff0000") & _
             vbcrlf&"</td>" & _
             vbcrlf&"</tr></table>"&ukong
  article_list_pagecute=temp1
end function

'================================================
'作    用：文章搜索功能模块
'参    数：
'  stit       ：文章
'================================================
function article_search_list(stit)
  dim temp1
  temp1=temp1&vbcrlf&"<table border=0>" & _
              vbcrlf&"<form name=article_sea_frm action='list.asp' method=get onsubmit=""javascript:frm_submitonce(this);"">" & _
              vbcrlf&"<input type=hidden name=action value='search'>" & _
              vbcrlf&"<tr height=30>" & _
              vbcrlf&"<td>"&img_skin("new")&"</td>" & _
              vbcrlf&"<td wdith=5></td>" & _
              vbcrlf&"<td>"&select_type(stit,0,0)&"</td>" & _
              vbcrlf&"<td wdith=5></td>" & _
              vbcrlf&"<td><select name=sea_type sizs=1><option value='topic'>"&stit&"标题</option><option value='keyes'>"&stit&"关键字</option><option value='username'>发布人</option></seelct></td>" & _
              vbcrlf&"<td wdith=5></td>" & _
              vbcrlf&"<td><select name=sea_term sizs=1><option value='all'>满足所有条件</option><option value='only'>满足一个条件</option></seelct></td>" & _
              vbcrlf&"<td wdith=5></td>" & _
              vbcrlf&"<td><input type=text name=keyword size=20 maxlength=20 title='多个关键字请用 空格 格开' class=bg_search></td>" & _
              vbcrlf&"<td wdith=5></td>" & _
              vbcrlf&"  <td><input type=submit class=btn value='搜索' onclick=""javascript:return article_sea('"&stit&"');""></td>" & _
              vbcrlf&"</tr></form></table>" & _
              vbcrlf&"<script language=javascript>" & _
              vbcrlf&"function article_sea(stit)" & _
              vbcrlf&"{" & _
              vbcrlf&"  if (document.article_sea_frm.keyword.value==""请输入关键字"")" & _
              vbcrlf&"  {" & _
              vbcrlf&"    alert('请在搜索"&stit&"前先输入要查询的 关键字 ！');" & _
              vbcrlf&"    document.article_sea_frm.keyword.focus();" & _
              vbcrlf&"    return false;" & _
              vbcrlf&"  }" & _
              vbcrlf&"}" & _
              vbcrlf&"</script>"
  article_search_list=temp1
end function

'================================================
'作    用：分类文章具体显示功能模块
'================================================
sub article_more(m_nummer,m_num,m_title)
  dim sqladd,sqladd_head,sqladd_end,nums,n_username,n_topic,n_tim,mhead,cname,sname,tmp,pages
  rssum=0
  nums=nummer
  sqladd_head=""
  sqladd_end=""
  select case action
  case "search"
    mhead=m_title&"&nbsp;→&nbsp;"&tit
    if cint(sid)>0 then sqladd=" and c_id="&cid
    if cint(sid)>0 then sqladd=sqladd&" and s_id="&sid
    sea_type=trim(request.querystring("sea_type"))
    keyword=joekoe_cms.code_form(request.querystring("keyword"))
    sea_term=trim(request.querystring("sea_term"))
    if sea_type<>"username" then sea_type="topic"
    if sea_term<>"only" then sea_term="all"
    sqladd_end=sql_key(keyword,sea_type,2,sea_term)
    if sqladd_end<>"" then
      sqladd=sqladd&" and "&sqladd_end
      sqladd_end=""
      mhead=mhead&"（关键字："&keyword&"）"
    end if
    pageurl=pageurl&"keyword="&server.urlencode(keyword)&"&sea_type="&sea_type&"&sea_term="&sea_term&"&"
  case "hot"
    mhead=m_title&"&nbsp;→&nbsp;"&tit&"（最新"&m_nummer&"条）"
    sqladd=""
    sqladd_head=" top "&m_nummer
    sqladd_end=" counter desc,"
  case "pic"
    mhead=m_title&"&nbsp;→&nbsp;"&tit
    sqladd=" and ispic=1"
  case "good"
    mhead=m_title&"&nbsp;→&nbsp;"&tit
    sqladd=" and istop=1"
  case else
    sql="select c_name from jk_class where c_id="&cid
    sqladd=" and c_id="&cid
    if cint(sid)>0 then 
      sqladd=" and s_id="&sid
      sql="select jk_class.c_name,jk_sort.s_name from jk_sort inner join jk_class on jk_sort.c_id=jk_class.c_id where jk_sort.c_id="&cid&" and jk_sort.s_id="&sid
    end if
    set rs=joekoe_cms.exec(sql,1)
    if rs.eof then
      rs.close
      call article_list(6,30)
      exit sub
    end if
    cname=rs("c_name")
    if cint(sid)>0 then sname=rs("s_name")
    rs.close
    mhead=m_title&"&nbsp;→&nbsp;"&cname
    if sid>0 and sname<>"" then mhead=mhead&"&nbsp;→&nbsp;"&sname
  end select
  sql="select"&sqladd_head&" id,topic,tim,username,counter,emoney,power,tcolor from article where hidden=1"&sqladd&" order by "&sqladd_end&"id desc"
  call joekoe_cms.exec("",-1)
  rs.open sql,conn,1,1
  if not(rs.eof) then rssum=rs.recordcount
  call format_pagecute()
  if cint(viewpage)>1 then rs.move (viewpage-1)*nummer
  if int(viewpage*nummer)>int(rssum) then nums=nummer-(viewpage*nummer-rssum)
  for i=1 to nums
    n_username=rs("username")
    n_topic=rs("topic")
    n_tim=rs("tim")
    n_tim=joekoe_cms.time_type(n_tim,1)
    tmp=tmp&article_topic_type(m_num,rs("id"),n_username,n_topic,n_tim,rs("counter"),false,2,rs("emoney"),rs("power"),rs("tcolor"))
    rs.movenext
  next
  rs.close
  if action<>"hot" then
    pages=article_list_pagecute(nummer,rssum,viewpage,thepages,pageurl)
  end if
  call article_bar_top(mhead,"<table border=0 cellspacing=1 cellpadding=2 width='100%'>"&tmp&"</table>"&pages,"")
end sub

'================================================
'作    用：所有文章显示功能模块
'================================================
sub article_list(n_num,c_num)
response.write "<table cellspacing=0 cellpadding=0 border=0  width='100%'>"
  dim nsid,nsname,srs,ssql,sqla,n_username,n_topic,n_tim,sid_num,tmp
  sid_num=0
  ssql="select s_id,s_name from jk_sort where c_id="&cid&" order by s_order"
  set srs=joekoe_cms.exec(ssql,1)
  do while not srs.eof
    sid_num=1
    nsid=srs("s_id")
    nsname=srs("s_name")
    sqla=" and s_id="&nsid
    sql="select top "&n_num&" id,topic,tim,username,counter,emoney,power,tcolor from article where hidden=1 and s_id="&nsid&" order by id desc"
    set rs=joekoe_cms.exec(sql,1)
    do while not rs.eof
      sid_num=2
      n_username=rs("username")
      n_topic=rs("topic")
      n_tim=rs("tim")
      n_tim=joekoe_cms.time_type(n_tim,1)
      tmp=tmp&article_topic_type(35,rs("id"),n_username,n_topic,n_tim,rs("counter"),false,2,rs("emoney"),rs("power"),rs("tcolor"))
      rs.movenext
    loop
    rs.close
	response.write "<tr><td  valign='top' align='center'>"
    call article_bar_top(nsname,"<table border=0 width='100%'>"&tmp&"</table>","list.asp?action=more&c_id="&ncid)
    response.write "</td>"
	tmp=""
    srs.movenext
	if srs.eof then
	response.write "<td width=3></td><td   valign='top' align='center'>&nbsp</td></tr>"
	exit do
	end if
    sid_num=1
    nsid=srs("s_id")
    nsname=srs("s_name")
    sqla=" and s_id="&nsid
    sql="select top "&n_num&" id,topic,tim,username,counter,emoney,power,tcolor from article where hidden=1 and s_id="&nsid&" order by id desc"
    set rs=joekoe_cms.exec(sql,1)
    do while not rs.eof
      sid_num=2
      n_username=rs("username")
      n_topic=rs("topic")
      n_tim=rs("tim")
      n_tim=joekoe_cms.time_type(n_tim,1)
      tmp=tmp&article_topic_type(35,rs("id"),n_username,n_topic,n_tim,rs("counter"),false,2,rs("emoney"),rs("power"),rs("tcolor"))
      rs.movenext
    loop
    rs.close
	response.write "<td width=3></td><td  valign='top' align='center'>"
    call article_bar_top(nsname,"<table border=0 width='100%'>"&tmp&"</table>","list.asp?action=more&c_id="&ncid)
    response.write "</td></tr>"
	tmp=""
    srs.movenext
  loop
  srs.close
  set srs=nothing
  'if sid_num>1 then
   ' action="more"
   ' call article_more(nummer,30,tit)
  'end if
  response.write "</table>"
end sub

'================================================
'作    用：所有文章按照分类显示功能模块
'================================================
sub article_main_list(n_num,c_num)
response.write "<table cellspacing=0 cellpadding=0 border=0  width='100%'>"
  dim ncid,ncname,crs,csql,sqla,n_username,n_topic,n_tim,tmp
  csql="select c_id,c_name from jk_class where nsort='"&n_sort&"' order by c_order"
  set crs=joekoe_cms.exec(csql,1)
  do while not crs.eof
    ncid=crs("c_id")
    ncname=crs("c_name")
    sqla=" and c_id="&ncid
    sql="select top "&n_num&" id,topic,tim,username,counter,emoney,power,tcolor from article where hidden=1 and c_id="&ncid&" order by id desc"
    set rs=conn.execute(sql)
    do while not rs.eof
      n_username=rs("username")
      n_topic=rs("topic")
      n_tim=rs("tim")
      n_tim=joekoe_cms.time_type(n_tim,1)
      tmp=tmp&article_topic_type(35,rs("id"),n_username,n_topic,n_tim,rs("counter"),false,2,rs("emoney"),rs("power"),rs("tcolor"))
      rs.movenext
    loop
    rs.close
    response.write "<tr><td valign='top' align='center'>"
    call article_bar_top(ncname,"<table border=0 width='100%'>"&tmp&"</table>","list.asp?action=more&c_id="&ncid)
	response.write "</td>"
    tmp=""
    crs.movenext
    if crs.eof then
	response.write "<td width=3></td><td  valign='top' align='center'>&nbsp</td></tr>"
	exit do
	end if
	ncid=crs("c_id")
    ncname=crs("c_name")
    sqla=" and c_id="&ncid
    sql="select top "&n_num&" id,topic,tim,username,counter,emoney,power,tcolor from article where hidden=1 and c_id="&ncid&" order by id desc"
    set rs=conn.execute(sql)
    do while not rs.eof
      n_username=rs("username")
      n_topic=rs("topic")
      n_tim=rs("tim")
      n_tim=joekoe_cms.time_type(n_tim,1)
      tmp=tmp&article_topic_type(35,rs("id"),n_username,n_topic,n_tim,rs("counter"),false,2,rs("emoney"),rs("power"),rs("tcolor"))
      rs.movenext
    loop
    rs.close
    response.write "<td width=3></td><td valign='top' align='center'>"
    call article_bar_top(ncname,"<table border=0 width='100%'>"&tmp&"</table>","list.asp?action=more&c_id="&ncid)
	response.write "</td></tr>"
    tmp=""
    crs.movenext
	
  loop
  crs.close
  set crs=nothing
response.write "</table>"
end sub
%>
