<!-- #include file="../common/include/con_help.asp" -->
<!-- #include file="../include/jk_pagecute.asp" -->
<!-- #include file="../include/jk_page_cute.asp" -->
<%
dim nummer,nums,rssum,page,viewpage,thepages,pageurl,sql_add,sql_order
iframe=true
nummer=dim_num(0)
nums=nummer
page=1

index_url="user_action"
tit_fir="注册用户"
select case action
case "emoney"
  sql_order="emoney desc"
  tit="财富排行"
case "top"
  sql_order="bbs_counter desc"
  tit="发贴排行"
case "integral"
  sql_order="integral desc"
  tit="积分排行"
case else
  sql_order="id desc"
  tit="用户列表"
end select

call web_head(0,0,0,0,0)
'----------------------------左边 开始----------------------------
call left_help()
call left_action()
'----------------------------左边 结束----------------------------
call web_center(0)
'----------------------------中间 开始----------------------------
%>
<table cellspacing=1 cellpadding=4 class=table>
<tr align=center>
<td class=td width='7%'>序号</td>
<td class=td width='20%'>用户名称</td>
<td class=td width='7%'>类型</td>
<td class=td width='7%'>性别</td>
<td class=td width='10%'>积分</td>
<td class=td width='10%'>发贴</td>
<td class=td width='12%'><%response.write joekoe_cms.web_unit%></td>
<td class=td <%response.write dd1%>>注册时间</td>
<td class=td width='7%'>短信</td>
</tr>
<%
sql="select count(id) from user_data where hidden=1"
set rs=joekoe_cms.exec(sql,1)
rssum=rs(0)
rs.close
call format_pagecute()
sql="select top "&nummer*viewpage&" id,username,power,sex,bbs_counter,integral,emoney,tim from user_data where hidden=1 order by "&sql_order
call joekoe_cms.exec(sql,-1)
rs.open sql,conn,0,1
if int(viewpage)>1 then rs.move (viewpage-1)*nummer
if int(viewpage*nummer)>int(rssum) then nums=nummer-(viewpage*nummer-rssum)
for i=1 to nums
  response.write vbcrlf&user_action_type(i+(viewpage-1)*nummer,rs("username"),rs("power"),rs("sex"),rs("bbs_counter"),rs("integral"),rs("emoney"),joekoe_cms.time_type(rs("tim"),4))
  rs.movenext
next
rs.close
pageurl="?action="&action&"&"
%>
<tr><td class=trb colspan=9 height=<%response.write m_hei%>>
&nbsp;现有&nbsp;<font class=red><%response.write rssum%></font>&nbsp;位<%response.write tit_fir%>
&nbsp;页次：<font class=red><%response.write viewpage%></font>/<font class=red><%response.write thepages%></font>&nbsp;
&nbsp;分页：<%response.write jk_pagecute(nummer,thepages,viewpage,pageurl,8,"#ff0000")%>
</td></tr>
</table>
<table border=0><tr><td height=30><%response.write img_user%></td></tr></table>
<%
response.write ukong
'----------------------------中间 结束----------------------------
call web_end(0,0)

function user_action_type(u_i,u_username,u_power,u_sex,u_bbs_counter,u_integral,u_emoney,u_tim)
  dim temp1
  temp1=temp1&vbcrlf&"<tr class=tr align=center>" & _
              vbcrlf&"<td class=tims>"&u_i&"</td>" & _
              vbcrlf&"<td align=left>"&format_user_name(u_username,0,"")&"</td>" & _
              vbcrlf&"<td>"&user_power(u_power)&"</td>" & _
              vbcrlf&"<td>"&user_sex(u_sex)&"</td>" & _
              vbcrlf&"<td align=right class=blue>"&u_integral&"</td>" & _
              vbcrlf&"<td align=right>"&u_bbs_counter&"</td>" & _
              vbcrlf&"<td align=right class=red2>"&u_emoney&"&nbsp;"&img_emoney&"</td>" & _
              vbcrlf&"<td>"&u_tim&"</td>" & _
              vbcrlf&"<td><a href='mail.asp?action=msg_write&accept="&u_username&"' targe=_blankk><img src='"&joekoe_cms.web_dir_skin&"mail/msg.gif' border=0 alt='给 "&u_username&" 发短信'></a></td>" & _
              vbcrlf&"</tr>"
  user_action_type=temp1
end function

function user_power(u_power)
  dim fi,pdim,pnum,pdim2,temp1
  temp1="<font class=gray>err</font>"
  pdim=dim_user
  pnum=ubound(pdim)
  for fi=0 to pnum
    if pdim(fi)<>"" or var_null(pdim(fi))<>"" then
      pdim2=split(pdim(fi),":")
      if u_power=pdim2(0) then
        temp1="<img src='"&joekoe_cms.web_dir_skin&"small/icon_"&u_power&".gif' border=0 alt='"&pdim2(1)&"'>"
      end if
    end if
  next
  if isarray(pdim) then erase pdim
  if isarray(pdim2) then erase pdim2
  user_power=temp1
end function

function user_sex(u_sex)
  dim temp1
  temp1="<img src='"&joekoe_cms.web_dir_skin&"small/boy.gif' alt='"&web_n_boy&"' border=0>"
  if not u_sex then temp1="<img src='"&joekoe_cms.web_dir_skin&"small/girl.gif' alt='"&web_n_girl&"' border=0>"
  user_sex=temp1
end function
%>