<%
dim csid,class_td
class_td=""

function cod_type()
  dim a
  a=trim(request.form("cod"))
  if a="" or isnull(a) then a=1
  if not(isnumeric(a)) then a=1
  if int(a)<>2 then a=1
  cod_type=a
end function

function cs_nd(csv)
  dim csnd
  cs_nd=true
  csnd=trim(request.form("csnd"))
  if len(csv)<1 then
    cs_nd=false
    exit function
  end if
  if csnd="yes" then
    if isnumeric(csv) then
      cs_nd=false
      exit function
    end if
  end if
end function

'call html_edit(rs("cod"),"add_frm","word")
sub html_edit(cods,fn,wn,class_s)
  dim cod
  cod=cods
  if cod="" or isnull(cod) then cod=1
%>
<tr <%response.write class_td%>>
<td>支持模式：</td>
<td>
  <table border=0 cellspacing=0 cellpadding=0>
  <tr>
  <td><input <%response.write class_td%> type=radio name=cod onclick="document.all.ubb_help.style.display='';document.all.html_help.style.display='none';" value='1'<%if cod<>2 then response.write " checked"%>>&nbsp;支持UBB</td>
  <td>&nbsp;<input <%response.write class_td%> type=radio name=cod onclick="document.all.ubb_help.style.display='none';document.all.html_help.style.display='';" value='2'<%if cod=2 then response.write " checked"%>>&nbsp;支持HTML</td>
  <td id=html_help style="display:<%
  if cod=2 then
    response.write "true"
  else
    response.write "none"
  end if%>;">&nbsp;&nbsp;&nbsp;&nbsp;<a href="###" onclick="javascript:open_win('htmledit/html_edit.htm?bodyID=<%response.write fn&"."&wn%>&htmlableID=<%response.write fn&"."&wn%>','html_edit',545,360,'no');">打开 HTML 编辑器</a></td>
  </tr>
  </table>
</td>
</tr>
<tr <%response.write class_s%> id=ubb_help style="display:<%
  if cod=2 then
    response.write "none"
  else
    response.write "true"
  end if%>;" height=35>
<td><%call frm_ubb_type(class_s)%></td>
<td><%call frm_ubb(fn,wn,"&nbsp;")%></td>
</tr>
<%
end sub

sub sql_cid_sid(sqlvar)
  if cid<>0 then
    if sqlvar="" then
      sqlvar=" where c_id="&cid
    else
      sqlvar=sqlvar&" and c_id="&cid
    end if
    pageurl=pageurl&"c_id="&cid&"&"
    if sid<>0 then
      sqlvar=sqlvar&" and s_id="&sid
      pageurl=pageurl&"s_id="&sid&"&"
    end if
  end if
end sub

sub chk_cid_sid()
  if isnumeric(csid) then
    cid=csid
    sid=0
  else
    cid=mid(csid,1,instr(csid,"_")-1)
    sid=mid(csid,instr(csid,"_")+1,len(csid))
  end if
end sub

sub admin_cid_sid()
  cid=trim(request.querystring("c_id"))
  sid=trim(request.querystring("s_id"))
  if not(isnumeric(cid)) then cid=0
  if not(isnumeric(sid)) then sid=0
  cid=int(cid)
  sid=int(sid)
end sub

sub left_sort(spageurl,t2)
  'response.write vbcrlf&"<table border=0 width='85%' align=center><tr><td class=htd>"
  dim rs2,sql2,sql3,rs3,snid,snow_id
  sql2="select c_id,c_name from jk_class where nsort='"&nsort&"' order by c_order,c_id"
  set rs2=joekoe_cms.exec(sql2,1)
  do while not rs2.eof
    snid=int(rs2(0))
    if cid=snid then
      response.write vbcrlf&img_admin("s_left_sort","")&"&nbsp;<a href='"&spageurl&"c_id="&snid&"'><b><font class=red2>"&rs2(1)&"</b></font></a><br>"
    else
      response.write vbcrlf&img_admin("s_left_sort","")&"&nbsp;<a href='"&spageurl&"c_id="&snid&"'>"&rs2(1)&"</a><br>"
    end if
    sql3="select s_id,s_name from jk_sort where c_id="&snid&" order by s_order,s_id"
    set rs3=joekoe_cms.exec(sql3,1)
    do while not rs3.eof
      snow_id=int(rs3(0))
      if sid=snow_id then
        response.write vbcrlf&"　<a href='"&spageurl&"c_id="&snid&"&s_id="&snow_id&"'><font class=blue>"&rs3(1)&"</a></a><br>"
      else
        response.write vbcrlf&"　<a href='"&spageurl&"c_id="&snid&"&s_id="&snow_id&"'>"&rs3(1)&"</a><br>"
      end if
      rs3.movenext
    loop
    rs3.close
    set rs3=nothing
    rs2.movenext
  loop
  rs2.close
  set rs2=nothing
  'response.write vbcrlf&"</td></tr></table>"
end sub

sub chk_csid(n_sort,cid,sid)
  dim sql2,rs2,sql3,rs3,csnd,now_id,n_id
  csnd="no"
  response.write "<select name=c_id size=1>"
  sql3="select c_id,c_name from jk_class where nsort='"&n_sort&"' order by c_order,c_id"
  set rs3=joekoe_cms.exec(sql3,1)
  do while not rs3.eof
    n_id=int(rs3(0))
    response.write vbcrlf&"<option value='"&n_id&"' class=bg_2"
    if cid=n_id then response.write " selected"
    response.write ">"&rs3(1)&"</option>"
    sql2="select s_id,s_name from jk_sort where c_id="&n_id&" order by s_order,s_id"
    set rs2=joekoe_cms.exec(sql2,1)
    do while not rs2.eof
      now_id=int(rs2(0))
      csnd="yes"
      response.write vbcrlf&"<option value='"&n_id&"_"&now_id&"'"
      if sid=now_id then response.write " selected"
      response.write ">　"&rs2(1)&"</option>"
      rs2.movenext
    loop
    rs2.close
    set rs2=nothing
    rs3.movenext
  loop
  rs3.close
  set rs3=nothing
  response.write "</select><input type=hidden name=csnd value='"&csnd&"'>"&redx&"如有二级分类，选一个二级分类"
end sub

sub chk_power(pvar,power,pt)
  dim dim_t
  response.write "<tr "&class_td&"><td>"&pvar&"权限：</td><td>"
  for i=0 to ubound(dim_user)
    dim_t=split(dim_user(i),":")
    response.write vbcrlf&"<input "&class_td&" type=checkbox name=power value='"&i+1&"' class=bg_1"
    if instr(1,"."&power&".","."&i+1&".")>0 or pt=1 then response.write " checked"
    response.write ">"&dim_t(1)
  next
  response.write vbcrlf&"<input "&class_td&" type=checkbox name=power value='0' class=bg_1"
  if instr(1,"."&power&".",".0.")=0 then response.write " checked"
  response.write ">游客</td></tr>"
end sub

sub chk_emoney(ee)
  response.write joekoe_cms.web_unit&"：<input type=text name=emoney value='"&ee&"' size=6 maxlength=10>"
end sub
%>