<!--#include file="conn.asp"-->
<%
'-------------------------------------
'功能：处理点出的程序
'天天智能友情链接管理系统
'天天DV网制作 http://www.ttdv.cn
'博大网址库http://www.ip126.com

'可自由传播和免费使用，但必须保留此完整版权信息
'本程序撷取了ITlearner、博大网址库智能友情链接系统、飞
'越智能友情链接系统等优秀程序中的源代码，对他们的作者表示感谢
'-------------------------------------

dim id,username,comeurl,flag,condition
username=hx.checkstr(request.querystring("username"),12)

id=request.form("id")
flag = 0

if id<>"" and isnumeric(id) then
	flag = 1
	condition = "id="&id
	comeurl = hx.checkstr(request.form("comeurl"),200)
else
	if username<>"" then
	flag = 1
	condition = "username='"&username&"'"
	comeurl=hx.checkstr(Request.ServerVariables("http_referer"),200)
	end if	
end if

if flag = 0 then
	CloseDatabase
	Response.Redirect("http://www.99shik.cn/link/")
end if


dim rs,sql
dim tturl
set rs=server.createobject("adodb.recordset")
sql="select TOP 1 tturl,outc,outj,outp,outdate,fromdate,username from tt_Link where "&condition
rs.open sql,conn,1,2
if not rs.eof then
	tturl=rs("tturl")
	if left(tturl,7)<>"http://" then tturl="http://" & tturl
	username = rs("username")
	If comeurl<>"" and not hx.isrec(1) then
		rs("outc")=rs("outc")+1
		if DateDiff("d",rs("outdate"),Date())=0 then
			rs("outj")=rs("outj")+1
		else
			rs("outj")=1
		end if
		rs("outdate")=Now()
		rs.update
		rs("outp")=rs("outc")/(DateDiff("d",rs("fromdate"),Date())+1)
		rs.update
	end if
		
else
   tturl=WebUrl
end if
rs.close
set rs=nothing
set hx=nothing

Response.Redirect tturl
%>