<!--#include file="conn.asp"-->
<!--#include file="md5.asp"-->
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN" 
    "http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
<title>申请友情链接_<%=WebName & ChannelName%> - Powered By ttdv</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="style.css">
</head>
<script language=javascript src=images/mouse_on_title.js></script>
<script LANGUAGE=JavaScript>
  function textLimitCheck(thisArea, maxLength){
    if (thisArea.value.length > maxLength){
      alert(maxLength + ' 个字限制. \r超出的将自动去除.');
      thisArea.value = thisArea.value.substring(0, maxLength);
      thisArea.focus();
    }
    /*回写span的值，当前填写文字的数量*/
    messageCount.innerText = thisArea.value.length;
  }
</script>
<BODY background="images/back.gif">
<!--#include file="top.asp"-->
<div class="bt<%=skin%>" > 您的位置:<a href="<%=WebUrl%>">首页</a> -- <a href="index.asp"><%=ChannelName%></a> -- <a href="addlink.asp" >申请友情链接</a></div>
<div class="bt<%=skin%>"><br>
  <%
if request("action")="addlink" then
call addlink
else
call showaddform
end if
sub showaddform
%>
  <p>申请流程：填写资料 -> 获取代码 -> 放到自己的主页上 -> 点击一次到我站 -> 完成</p>
  <form id="applyform" method="post" action="?action=addlink">
  <table width="90%" border="0" cellpadding="3" cellspacing="1" bgcolor="#000000" align="center">
      <tr class="tr<%=skin%>">
        <td width="100" align="center">用 户 名：</td>
        <td><input name="username" type="text" id="username" size="12" maxlength="12">&nbsp;&nbsp; <img src=images/memo.gif alt="不能超过12个字符（6个汉字）"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">网站名称：</td>
        <td><input name="ttname" type="text" id="ttname" size="12" maxlength="30">&nbsp;&nbsp; <img src=images/memo.gif alt="不能超过30个字符（15个汉字）"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">网站地址：</td>
        <td><input name="tturl" type="text" id="tturl" size="50" maxlength="100">&nbsp;&nbsp; <img src=images/memo.gif alt="不能超过100个字符"><br>如果您站也使用类似友情链接管理系统，请先在贵站给本站注册一个ID号，再将链接代码填入此栏</td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">图片地址：</td>
        <td><input name="ttlogo" type="text" id="ttlogo" size="50" maxlength="100">&nbsp;&nbsp; <img src=images/memo.gif alt="可选项，不能超过100个字符 <br>（图片大小尺寸为:88*31，如果暂时没有，请留空）"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">网站类型：</td>
        <td><select name="webtype" size="1" id="webtype">
            <%call hx.listwebtype(0,0)%>
          </select>&nbsp;&nbsp; <img src=images/memo.gif alt="请正确选择您网站的类型"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">密　　码：</td>
        <td><input name="password" type="password" id="password" size="12" maxlength="12">&nbsp;&nbsp; <img src=images/memo.gif alt="4~12个字符"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">密码确认：</td>
        <td><input name="pwdconfirm" type="password" id="pwdconfirm" size="12" maxlength="12">&nbsp;&nbsp; <img src=images/memo.gif alt="请再输一遍确认"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">密码问题：</td>
        <td><input name="problem" type="text" id="problem" size="12" maxlength="12">&nbsp;&nbsp; <img src=images/memo.gif alt="用于密码保护和找回密码。12个字符内"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">密码答案：</td>
        <td><input name="answer" type="text" id="answer" size="12" maxlength="12">&nbsp;&nbsp; <img src=images/memo.gif alt="找回密码时要回答的内容。12个字符内"></td>
      </tr> 
      <tr class="tr<%=skin%>">
        <td align="center">答案确认：</td>
        <td><input name="answerconfirm" type="text" id="answerconfirm" size="12" maxlength="12">&nbsp;&nbsp; <img src=images/memo.gif alt="请再输一遍确认"></td>
      </tr>              
      <tr class="tr<%=skin%>">
        <td align="center">联系邮箱：</td>
        <td><input type="text" name="email" size="30" maxlength="50">&nbsp;&nbsp; <img src=images/memo.gif alt="请输入有效的邮件地址，不能超过50个字符认"></td>
      </tr>
      <tr class="tr<%=skin%>">
        <td align="center">邮件列表：</td>
        <td><input type="radio" name="maillist" value="1" id="maillist" >
                 订阅&nbsp;&nbsp;&nbsp;&nbsp;
                <input type="radio" name="maillist" value="0" id="maillist" checked>不订阅&nbsp;&nbsp; <img src=images/memo.gif alt="如果想获得本站最新资讯请加入邮件列表"></td>
      </tr>      
      <tr class="tr<%=skin%>">
        <td align="center">网站简介：</td>
        <td valign="middle"><textarea name="ttinfo" cols="70" rows="4" id="ttinfo" onkeyUp="textLimitCheck(this, 100);"></textarea>&nbsp;&nbsp; <img src=images/memo.gif alt="不能超过100个字符（50个汉字）"><br>限 100 个字符 已输入 <font color="#CC0000"><span id="messageCount">0</span></font> 个字</td>
      </tr>
      <tr class="tr<%=skin%>">
        <td colspan="2" align="center" class="td"><input type="submit" value=" 确 定 " name="yes">
          <input name="reset" type="reset" 
value=" 重 写 ">
        </td>
      </tr>
  </table>
  </form>
  <%end sub%>
  <%sub addlink
dim username,ttname,tturl,ttlogo,email,password,pwdconfirm,webtype,ttinfo,maillist,problem,answer,answerconfirm
username=hx.checkstr(request.form("username"),12)
ttname=hx.checkstr(request.form("ttname"),30)
tturl=hx.checkstr(request.form("tturl"),100)
ttlogo=hx.checkstr(request.form("ttlogo"),100)
email=hx.checkstr(request.form("email"),50)
maillist=request.form("maillist")
password=hx.checkstr(request.form("password"),12)
pwdconfirm=hx.checkstr(request.form("pwdconfirm"),12)
problem=hx.checkstr(request.form("problem"),12)
answer=hx.checkstr(request.form("answer"),12)
answerconfirm=hx.checkstr(request.form("answerconfirm"),12)
webtype=request.form("webtype")
ttinfo=hx.checkstr(request.form("ttinfo"),100)

dim blnerror,strerror
blnerror=false
if username="" or ttname="" or tturl="" or password="" or problem="" or ttinfo="" or email="" then
	blnerror=true
	strerror="<li>请检查是否有必填信息没有填写！</li>"
end if

if blnerror=false then
if hx.blnfilter(ttname,1) then
	blnerror = true
	strerror = strerror & "<li>网站名称不能包含某些特殊关键词！</li>"
end if
if hx.blnfilter(ttinfo,1) then
	blnerror = true
	strerror = strerror & "<li>网站简介不能包含某些特殊关键词！</li>"
end if
if hx.blnfilter(tturl,2) then
	blnerror = true
	strerror = strerror & "<li>此域名已经被屏蔽！</li>"
end if

if ttlogo="" then
ttlogo="http://" & hx.BaseUrl & "images/wu.gif"
end if
if left(ttlogo,7)<>"http://" then ttlogo="http://" & ttlogo
if left(tturl,7)<>"http://" then tturl="http://" & tturl
'增强邮箱和网址的判断
if not CheckEmail(email) then
	blnerror = true
	strerror = strerror & "<li>联系邮箱不正确！</li>"
end if
'if not CheckUrl(tturl) then   '取消网址判断，否则使用类似链接系统的用户无法互相申请
'	blnerror = true
'	strerror = strerror & "<li>网址不正确！</li>"
'end if
if not isnumeric(webtype) then
	blnerror=true
	strerror=strerror & "<li>请正确选择网站类型！</li>"
end if
if len(password)<4 then 
	blnerror=true
	strerror=strerror & "<li>您的密码太短了！</li>"
end if
if password<>pwdconfirm then
	blnerror=true
	strerror=strerror & "<li>两次密码不相同！</li>"
end if
if answer<>answerconfirm then
	blnerror=true
	strerror=strerror & "<li>两次密码答案不相同！</li>"
end if
if problem=answer then
	blnerror=true
	strerror=strerror & "<li>密码问题与密码答案不要相同！</li>"
end if

end if

if blnerror=false then
	dim rs,sql
	set rs=hx.execute("select username from tt_Link where username='"&username&"'")
	if not rs.eof then
		blnerror=true
		strerror=strerror & "<li>抱歉，用户名已经存在，请重新选择一个用户名</li>"		
	end if
	set rs=nothing	
end if

if blnerror=false then
'检测是否是同一域名 V1.6新增 051104
if IsDomainLimit = 1 then
	dim domain
	domain = mid(tturl,8)
	if instr(domain,"/")>0 then
	domain = left(domain,instr(domain,"/"))
	end if
	set rs=hx.execute("select username from tt_Link where tturl like '%"&domain&"%'")
	if not rs.eof then
		blnerror=true
		strerror=strerror & "<li>抱歉，此域名已经存在，系统限制一个域名只能注册一次。</li>"		
	end if
	set rs=nothing		
end if
end if


if blnerror=true then
	response.write strerror
	response.write "<p><< <a href=""javascript:history.go(-1)"">返回上一页 </a></p>"
else
	sql="select top 1 * from tt_Link"
	set rs=server.CreateObject("adodb.recordset")
	rs.open sql,conn,1,2
	rs.AddNew
	rs("username")=username
	rs("email")=email
	rs("maillist")=maillist	
	rs("ttname")=ttname
	rs("webtype")=webtype
	rs("password")=md5(password)
	rs("problem")=problem
	rs("answer")=md5(answer)	
	rs("tturl")=tturl
	rs("ttinfo")=ttinfo
	rs("ttlogo")=ttlogo 
	if IsVerify = 1 then
		rs("isverify")=0	'不通过
	else
		rs("isverify")=1	'通过
	end if
	rs.Update
	rs.close
	set rs=nothing	

if emailkg=1 then
'获得信息发送邮件
dim welcome,mailbody,tmpt,jmail,ErrStr
welcome= ""&ttname&"在【"&webname&"】申请的友情链接代码"
mailbody = "恭喜您，贵站－"&ttname&"在【"&webname&"】申请的友情链接成功！谢谢您的信任和支持，本站将尽快审核！请及时将友情链接代码加在您站上，并点击进入本站一次，以免耽误审核时间。<br><b>本站链接代码：</b><br>站名：<font color=#FF6600>"&webname&"</font><br>网址：<font color=red>http://"&hx.BaseUrl&"ttindex.asp?id="&username&"</font><br>LOGO：http://"&hx.BaseUrl&"images/logo.gif<br>简介：<font color=red>"&WebAlt&"</font>"

'jmail邮件组件发送邮件开始，下面的值要先取得
Set jmail = Server.CreateObject("JMail.Message") 
jmail.silent = true '屏蔽例外错误，返回FALSE跟TRUE两值
jmail.Logging = true '启用邮件日志
jmail.Charset = "gb2312"  '邮件的文字编码为国标
jmail.ContentType = "text/html"    '邮件的格式为HTML格式
jmail.MailServerUserName = servemail '输入smtp服务器验证登陆名 （邮局中任何一个用户的Email地址） 
jmail.MailServerPassword = servekey '输入smtp服务器验证密码 （用户Email帐号对应的密码） 
jmail.From = webemail '发信人信箱，因有的服务器反垃圾邮件，此信箱最好与发信服务器同域用户的信箱！ 
jmail.FromName = webname '发件人姓名或公司名 
jmail.AddRecipient email '收件人Email 
jmail.Subject = welcome '邮件的标题 
jmail.Body = mailbody '邮件的内容
 'jmail.Prority = 1      '邮件的紧急程序,必须服务器支持，1 为最快，5 为最慢， 3 为默认值 
jmail.Send (servesmtp) '执行邮件发送smtp服务器地址（企业邮局地址）
ErrStr =jmail.errormessage '允许错误 
set jmail = nothing '关闭对象
'邮件发送结束
if ErrStr = "" then
response.Write "<script language=javascript>alert('恭喜！申请友情链接成功,请尽快把链接代码放上您站，并点击进入本站一次。系统已发送一封邮件到您的信箱。');</script>"	
else
response.Write "<script language=javascript>alert('申请成功！等待审核。请尽快把链接代码放上您站，并点击进入本站一次。');</script>"
end if	'发送结果判断结束
else
response.Write "<script language=javascript>alert('申请成功！等待审核。请尽快把链接代码放上您站，并点击进入本站一次。');</script>"
end if

%>
  <ul>
    <li><strong><font color="#FF0000">恭喜，申请友情链接成功！！！</font></strong></li>
    <%if IsVerify = 1 then%>
    <li>本站设置了注册的网站需要管理员审核才能显示，请注册后耐心等待管理员审核或者直接联系管理员。</li>
    <%end if%>    
    <li>请尽快加上本站提供的链接代码。如果超过一周没有放上链接，我站将删除贵站的资料。</li>
    <li>只有在你的主页上加入我站的链接后并点击一次后才有可能在我的主页上显示你的链接，并开始统计点击数。</li>
    <li>点入贡献越多，排名越前，前<%=LineLogo*LineNum%>名可以显示图标，其它则显示文字。</li>
    <li>站长推荐贵站使用文字链接，如果您愿意使用图标链接，请将图片拷贝到您的服务器上，可加快贵站显示此logo速度，并减少本站流量，谢谢！</li>
  </ul>
  <table width="100%" border="0" align="center">
    <tr valign="top">
      <td width="50%"><p>文字链接 <font color="#0000FF">代码：</font><br>
      网站名称：<%=WebName%><br>
      网&nbsp;&nbsp;&nbsp;&nbsp;址：http://<%=hx.BaseUrl%>ttindex.asp?id=<%=username%><br>
      网站简介：<%=WebAlt%><p>
      或：<br>
          <textarea name="textarea" style="width:96%;height:80px;"><a href="http://<%=hx.BaseUrl%>ttindex.asp?id=<%=username%>" target="_blank" title="<%=WebAlt%>"><%=WebName%></a></textarea>
        <p><font color="#0000FF">显示样式：</font><a href="http://<%=hx.BaseUrl%>ttindex.asp?id=<%=username%>" target="_blank" title="<%=WebAlt%>"><%=WebName%></a></p></td>
      <td width="50%"><p>图标链接<font color="#0000FF"> 代码：</font><br>
      网站名称：<%=WebName%><br>
      网&nbsp;&nbsp;&nbsp;&nbsp;址：http://<%=hx.BaseUrl%>ttindex.asp?id=<%=username%><br>
      图标地址：http://<%=hx.BaseUrl%>images/logo.gif<br>
      网站简介：<%=WebAlt%><p>
      或：<br>      
          <textarea name="textarea2" style="width:96%;height:80px;"><a href="http://<%=hx.BaseUrl%>ttindex.asp?id=<%=username%>" target="_blank"><img src="http://<%=hx.BaseUrl%>images/logo.gif" width="88" height="31" alt="<%=WebAlt%>" border="0"></a></textarea>
        </p>
        <p><font color="#0000FF">显示样式：</font><a href="http://<%=hx.BaseUrl%>ttindex.asp?id=<%=username%>" target="_blank"><img src="http://<%=hx.BaseUrl%>images/logo.gif" width="88" height="31" alt="<%=WebAlt%>" border="0"></a></p></td>
    </tr>
  </table>  
  <%
end if
end sub


'邮箱验证
Function CheckEmail(str)
		Dim re,a
		Set re = New RegExp
		re.IgnoreCase = True
		re.Global = True
		re.Pattern = "\w+([-+.]\w+)*@\w+([-.]\w+)*\.\w+([-.]\w+)*"
		a = re.Test(str)
		If a then 
			CheckEmail = True
		Else
			CheckEmail = False	
  End If	
end function
'网址验证
Function CheckUrl(str)
  Dim re,a
  Set re = New RegExp
  re.Pattern = "^https?:\/\/[\u4E00-\u9FA5a-zA-Z\.\/0-9]{3,}[\u4E00-\u9FA5a-zA-Z\/0-9]{2,}$" 
  re.IgnoreCase = False 
  a = re.Test(str)
  If a Then
    CheckUrl = true
  Else
    CheckUrl = false
  End If
End Function
%>
</div>
<!--#include file="under.asp"-->
<%set hx=nothing%>
</body>
</html>
