<%
function send_mail(s_username,s_email,s_topic,s_body)
  dim temp1
  temp1=s_username&"，你好！" & _
	vbcrlf& _
        vbcrlf& s_body & _
	vbcrlf& _
	vbcrlf&"--------------------------------------------------------" & _
	vbcrlf&"更多精彩信息请访问：" & _
	vbcrlf& _
	vbcrlf& web_dim(1) & _
	vbcrlf& web_dim(2) & _
	vbcrlf& _
	vbcrlf&"欢迎您的光临！" & _
	vbcrlf&"--------------------------------------------------------" & _
	vbcrlf&"注：本邮件为系统邮件！" & _
	vbcrlf&"邮件发送时间："&joekoe_cms.time_type(joekoe_cms.now_time,2)
  send_mail=send_jmail(s_email,"系统邮件："&s_topic&"（久久时空 99shik.cn）",temp1,"系统邮件管理员","fyp005@163.com")
end function

function send_jmail(j_sendname,j_Subject,j_HTMLBody,j_name,j_email)
  on error resume next
  dim Jmail
  Set Jmail=server.createobject("Jmail.Message")
  Jmail.Charset="gb2312"
  Jmail.Priority=2					'优先级
  Jmail.MailServerUserName="fyp005"		'这里换成您的SMTP验证帐号
  Jmail.MailServerPassword="yulianguanli"		'这里填写您的SMTP认证密码
  Jmail.From=j_email					'发信人邮件地址
  Jmail.FromName=j_name					'发信人姓名
  Jmail.Subject=j_Subject				'信件主题
  Jmail.AddRecipient j_sendname				'收信人地址
  Jmail.Body=j_HTMLBody					'TXT Mailbody参数是信件正文
  'JMail.HTMLBody=j_HTMLBody				'HTML信件正文
  Jmail.Send("smtp.163.com")				'发信的邮件服务器
  Set Jmail=nothing
  send_jmail=true
  if err then
    err.clear
    send_jmail=false
  end if
end function
%>