<%temp_interface_defray_receive_chinabank_handle=site.object_p%>
<!-- object[<%=site.object_p%>]::temp_interface_defray_receive_chinabank_handle -->
<%
dim v_oid '商户发送的v_oid定单编号
dim v_pmode ' 支付方式（字符串）
dim v_pstatus '支付状态 20（支付成功）30（支付失败）
dim v_pstring '支付结果信息 支付完成（当v_pstatus=20时）；失败原因（当v_pstatus=30时）；
dim v_amount '订单实际支付金额
dim v_moneytype '订单实际支付币种
dim remark1 '
dim remark2 '
dim v_md5str 'Md5校验串
dim key  '私钥值
dim text '
dim md5text '

'////////////////////////////////////////////////////////////////////////////////////////////////////////////
v_oid=request("v_oid")
v_pmode=request("v_pmode")
v_pstatus=request("v_pstatus")
v_pstring=request("v_pstring")
v_amount=request("v_amount")
v_moneytype=request("v_moneytype")
remark1=request("remark1")
remark2=request("remark2")
v_md5str=request("v_md5str")

key= site.temp.interface.defray.interface_key_send 
'md5校验
text = v_oid&v_pstatus&v_amount&v_moneytype&key
md5text = Ucase(trim(site.functions.EncodeMd5(text,32)))

If md5text<>v_md5str Then

	site.temp.interface.defray.suc = False

Else

	Select Case v_pstatus
	Case 20
		'支付通知验证成功
		site.temp.interface.defray.suc = True

	Case 30
		'支付通知验证失败
		site.temp.interface.defray.suc = False

	Case Else
		'支付通知验证过程中出现错误
		site.temp.interface.defray.suc = False

	End Select

End If

if not site.temp.interface.defray.suc then 	site.Error.info = "支付失败！"

'////////////////////////////////////////////////////////////////////////////////////////////////////////////
If site.temp.interface.defray.suc Then

	If site.temp.customer.Order.order_mark <> v_oid Then
		site.Error.info = "返回的订单号不符，支付失败！请联系管理员！"
		site.temp.interface.defray.suc = False
	Else
		If formatnumber(ccur("0"&site.temp.customer.Order.order_money),-1,-1) <> formatnumber(ccur("0"&v_amount),-1,-1)  Then
			site.Error.info = "订单金额不符，支付失败！请联系管理员！"
			site.temp.interface.defray.suc = False
		End If
	End If

End If

%>