<%temp_interface_defray_receive_westpay_handle=site.object_p%>
<!-- object[<%=site.object_p%>]::temp_interface_defray_receive_westpay_handle -->
<%
dim MerchantOrderNumber, WestPayOrderNumber, PaidAmount, MerchantID,objHttp

MerchantOrderNumber=request("MerchantOrderNumber") '和商户支付命令中的订单号相同
WestPayOrderNumber=request("WestPayOrderNumber")
PaidAmount=formatnumber(ccur("0"&request("PaidAmount")),-1,-1)  'WestPay传回的实际支付金额。用CCUR转为数字型。
MerchantID=request("MerchantID")
'注：商户必须根据我们传回商户原始订单号找到原始订单，比较实付金额和原始订单金额，相同才是支付成功。
'注：商户必须判断此商户ID是不是您的商户ID

'////////////////////////////////////////////////////////////////////////////////////////////////////////////

Set objHttp = Server.CreateObject("MSXML2.ServerXMLHTTP")
objHttp.open "POST", "http://www.yeepay.com/pay/ISPN.asp", False
'objHttp.open "POST", "http://202.200.239.226/class/get.asp", False
objHttp.setRequestHeader "Content-type", "application/x-www-form-urlencoded"
objHttp.Send Request.Form & "&cmd=validate"

If (objHttp.Status <> 200) Then
	'HTTP 错误处理
	site.temp.interface.defray.suc = False
Else
	Select Case objHttp.responseText
	Case "VERIFIED"
		'支付通知验证成功
		site.temp.interface.defray.suc = True

	Case "INVALID"
		'支付通知验证失败
		site.temp.interface.defray.suc = False

	Case Else
		'支付通知验证过程中出现错误
		site.temp.interface.defray.suc = False

	End Select

End If

if not site.temp.interface.defray.suc then 	site.Error.info = "支付失败！"

Set objHttp = Nothing
'////////////////////////////////////////////////////////////////////////////////////////////////////////////
If site.temp.interface.defray.suc Then

	If site.temp.customer.Order.order_mark <> MerchantOrderNumber Then
		site.Error.info = "返回的订单号不符，支付失败！请联系管理员！"
		site.temp.interface.defray.suc = False
	Else
		If site.temp.interface.defray.interface_id_send <> MerchantID Then
			site.Error.info = "不是本站的订单，支付失败！请联系管理员！"
			site.temp.interface.defray.suc = False
		Else
			If formatnumber(ccur("0"&site.temp.customer.Order.order_money),-1,-1) <> PaidAmount  Then
				site.Error.info = "订单金额不符，支付失败！请联系管理员！"
				site.temp.interface.defray.suc = False
			End If
		End If
	End If

End If

%>