<% @ Language="VBScript" %>
<% Option Explicit %>
<%
	'这是一些随IIS4附带的一些组件（默认的）
	Dim theInstalledObjects(8)
	theInstalledObjects(0) = "MSWC.AdRotator"
	theInstalledObjects(1) = "MSWC.BrowserType"
	theInstalledObjects(2) = "MSWC.NextLink"
	theInstalledObjects(3) = "MSWC.Tools"
	theInstalledObjects(4) = "MSWC.Status"
	theInstalledObjects(5) = "MSWC.Counters"
	theInstalledObjects(6) = "IISSample.ContentRotator"
	theInstalledObjects(7) = "IISSample.PageCounter"
	theInstalledObjects(8) = "MSWC.PermissionChecker"


Function IsObjInstalled(strClassString)
	On Error Resume Next
	IsObjInstalled = False
	Err = 0
	Dim xTestObj
	Set xTestObj = Server.CreateObject(strClassString)
	If 0 = Err Then IsObjInstalled = True
	Set xTestObj = Nothing
	Err = 0
End Function

%>
<HTML>
<HEAD>
<TITLE>检测你的服务器支持哪些asp组件的工具</TITLE>
</HEAD>
<BODY>
在下面的输入框中输入你要检测的组件的ProgId或则ClassId.
如果你没有输入的话，将使用默认值。
<FORM action=<%=Request.ServerVariables("SCRIPT_NAME")%> method=post>
	<input type=text value="" name="classname" size=40>
	<INPUT type=submit value=Submit>
	<INPUT type=reset value=Reset> 
</FORM>
<%
	Dim strClass
	strClass = Trim(Request.Form("classname"))
	If "" <> strClass then
		Response.Write strClass & "  "
		If Not IsObjInstalled(strClass) then
			Response.Write "<strong>没有安装，本主页提供站点不支持这个组件</strong>"
		Else
			Response.Write "安装了，本主页提供站点支持使用这个组件!"
		End If
		Response.Write "<P>" & vbCrLf
	Else
%>
<TABLE BORDER=0>
<%
	Dim i
	For i=0 to UBound(theInstalledObjects)
		Response.Write "<TR><TD>" & theInstalledObjects(i) & "</TD><TD>"
		If Not IsObjInstalled(theInstalledObjects(i)) Then 
			Response.Write "<strong>没有安装，本主页提供站点不支持这个组件</strong>"
		Else
			Response.Write "安装了，本主页提供站点支持使用这个组件!"
		End If
			Response.Write "</TD></TR>" & vbCrLf
	Next
%>
</TABLE>
<%
End If
%>
</BODY>
</HTML>